dev-python/scikit-learn: Bump to 1.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index 3034621670a0..355deb14527d 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.7.2.gh.tar.gz 7174108 BLAKE2B c9b2fb0a4480eb18ee4ab8c32d8d7e5e6c0f9ca9cbbdd207ff9c8acef046dc486f861aa7abefa5c528f976216ca90684b3080f2e00877bd2bfee8933665e3558 SHA512 354b2b084fc36cdef8ec9b2ff5cb77dd5d06bca34ff8a29bd34dc19608d591e62481e09b9d3fbf9afbf8e7ed935a2ca0845f22636b3c598555af5f5d087bacc8
+DIST scikit-learn-1.8.0.gh.tar.gz 7321445 BLAKE2B 3010843f019f97a845eb4184dbb0225bc6ef36e5af374811ea08492a78a85ece7ac5cf543c6bd33bad8faf6adbb2ea2412b3ea04e3a30cb7ea6b3d63da1a95a2 SHA512 801985d472894f896e9f277bbdef76388d9a53d821eaede95c43850d8e812d0a5cbaf16c15f2e495ec569a070f727b12729e346775e278afa11c30c713effb62
diff --git a/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
new file mode 100644
index 000000000000..038adf6a94ea
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV/_}.tar.gz
+		-> ${P/_}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.24.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	case ${ARCH} in
+		ppc64)
+			EPYTEST_DESELECT+=(
+				# TODO
+				ensemble/_weight_boosting.py::sklearn.ensemble._weight_boosting.AdaBoostRegressor
+			)
+	esac
+
+	rm -rf sklearn || die
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}