dev-cpp/antlr-cpp: add subslot to antlr4

The only consumer for antlr4 is mysql-workbench which links to it very
granularily. Add a subslot to antrl4-cpp to reflect this and trigger a
rebuild appropriately.

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-cpp/antlr-cpp/antlr-cpp-4.13.2-r1.ebuild b/dev-cpp/antlr-cpp/antlr-cpp-4.13.2-r1.ebuild
new file mode 100644
index 000000000000..ba6dad259e55
--- /dev/null
+++ b/dev-cpp/antlr-cpp/antlr-cpp-4.13.2-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="The ANTLR 4 C++ Runtime"
+HOMEPAGE="https://www.antlr.org/"
+SRC_URI="https://www.antlr.org/download/antlr4-cpp-runtime-${PV}-source.zip"
+
+LICENSE="BSD"
+SLOT="4/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-cpp/gtest )"
+BDEPEND="app-arch/unzip"
+
+src_unpack() {
+	mkdir "${S}" || die
+	cd "${S}" || die
+	unpack "antlr4-cpp-runtime-${PV}-source.zip"
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i -e "s|doc/libantlr$(ver_cut 1)|doc/${PF}|" CMakeLists.txt || die
+
+	# Give proper gtest find_package name
+	sed -i \
+		-e 's/gtest_main/GTest::gtest_main/' \
+		-e '/FetchContent_Declare/,/^$/ {
+			/\sURL https:\/\/github.com\/google\/googletest/aFIND_PACKAGE_ARGS NAMES GTest
+		}' runtime/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DANTLR_BUILD_CPP_TESTS=$(usex test)
+		-DANTLR_BUILD_SHARED=ON
+		-DANTLR_BUILD_STATIC=OFF
+		-DFETCHCONTENT_TRY_FIND_PACKAGE_MODE=ALWAYS
+	)
+	cmake_src_configure
+}