dev-cpp/glibmm: add 2.84.0

Closes: https://bugs.gentoo.org/942313
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-cpp/glibmm/glibmm-2.84.0.ebuild b/dev-cpp/glibmm/glibmm-2.84.0.ebuild
new file mode 100644
index 000000000000..a6b79c027ed5
--- /dev/null
+++ b/dev-cpp/glibmm/glibmm-2.84.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..13} )
+inherit gnome.org meson-multilib python-any-r1
+
+DESCRIPTION="C++ interface for glib2"
+HOMEPAGE="https://www.gtkmm.org https://gitlab.gnome.org/GNOME/glibmm"
+
+LICENSE="LGPL-2.1+"
+SLOT="2.68"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="gtk-doc debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.83.4:2[${MULTILIB_USEDEP}]
+	dev-libs/libsigc++:3[gtk-doc?,${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	gtk-doc? (
+		app-text/doxygen[dot]
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+"
+
+src_prepare() {
+	default
+
+	# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
+	sed -i -e '/giomm_tls_client/d' tests/meson.build || die
+
+	if ! use test; then
+		sed -i -e "/^subdir('tests')/d" meson.build || die
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwarnings=min
+		-Dbuild-deprecated-api=true
+		$(meson_native_use_bool gtk-doc build-documentation)
+		$(meson_use debug debug-refcounting)
+		-Dbuild-examples=false
+	)
+	meson_src_configure
+}