dev-cpp/rapidfuzz-cpp: Bump to 1.9.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-cpp/rapidfuzz-cpp/rapidfuzz-cpp-1.9.0.ebuild b/dev-cpp/rapidfuzz-cpp/rapidfuzz-cpp-1.9.0.ebuild
new file mode 100644
index 000000000000..6fb280d52d37
--- /dev/null
+++ b/dev-cpp/rapidfuzz-cpp/rapidfuzz-cpp-1.9.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Rapid fuzzy string matching in C++"
+HOMEPAGE="https://github.com/maxbachmann/rapidfuzz-cpp/"
+SRC_URI="
+	https://github.com/maxbachmann/rapidfuzz-cpp/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		>=dev-cpp/catch-3
+	)
+"
+
+src_prepare() {
+	# apparently "C++ best practices" don't mind fetching random stuff
+	# at build time
+	sed -i -e '/aminya/,/^)/d' test/CMakeLists.txt || die
+	find -name 'CMakeLists.txt' -exec \
+		sed -i -e 's:project_warnings::' {} + || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DRAPIDFUZZ_BUILD_TESTING=$(usex test)
+	)
+	cmake_src_configure
+}