dev-lang/micropython: version bump.

Courtesy of Mike Auty <ikelos@gentoo.org>.

Closes: https://bugs.gentoo.org/700362
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-lang/micropython/micropython-1.11.ebuild b/dev-lang/micropython/micropython-1.11.ebuild
new file mode 100644
index 000000000000..d1f7d57db774
--- /dev/null
+++ b/dev-lang/micropython/micropython-1.11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Python implementation for microcontrollers"
+HOMEPAGE="https://github.com/micropython/micropython"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+
+DEPEND="
+	virtual/libffi
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/${P}-prevent-stripping.patch" )
+
+src_compile() {
+	cd ports/unix || die
+
+	# 1) don't die on compiler warnings
+	# 2) remove /usr/local prefix references in favour of /usr
+	sed -i \
+		-e 's#-Werror##g;' \
+		-e 's#\/usr\/local#\/usr#g;' \
+		Makefile || die
+
+	emake CC="$(tc-getCC)" axtls
+	emake CC="$(tc-getCC)"
+}
+
+src_test() {
+	cd ports/unix || die
+	emake test
+}
+
+src_install() {
+	pushd ports/unix > /dev/null || die
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" DESTDIR="${D}" install
+	popd > /dev/null || die
+
+	# remove .git files
+	find tools -type f -name '.git*' -exec rm {} \; || die
+
+	dodoc -r tools
+	einstalldocs
+}