dev-libs/intel-compute-runtime: add 24.35.30872.32

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index b828d023e778..05b7f9ea06e0 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-24.35.30872.25.tar.gz 7375680 BLAKE2B 8aede769b46ecdb2eb49346bc87c1e58fbefa382e80419a301b00197fbdc977f62b001e7670a912a28c736aafc59e60d45a4c4d3e61331d6001307c184d3a4b8 SHA512 4e09f432f1f3a7f8c3b9a7bbd6981f2b26a837fc6f6b4459d21bb51fcce94a3c95726d23fb77be2664c7fbdf4dd270e1ec21af1bc815e718a5df865e8bbdac03
+DIST intel-compute-runtime-24.35.30872.32.tar.gz 7376572 BLAKE2B af924c111d288621ddcb14b9d77ff384c632668705e4858ed27424522b6c96e1e7b54012b202c6ade64da668681f3089d0a35d64ecb97ddec642ace8774b3e47 SHA512 2ac8dbefcc1a86b33afd78b8a1d30a959fb980e47402852514d43503df87ea70ea35f192243b78faedce749b3087f244631080f16ddb099a93ec79698176f6b5
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.32.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.32.ebuild
new file mode 100644
index 000000000000..50c31549953b
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.32.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0/1.5.30872"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND="
+	>=dev-util/intel-graphics-compiler-1.0.17791.18
+	>=media-libs/gmmlib-22.5.2:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.182:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-0.9.5:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.19.2:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}