dev-libs/intel-compute-runtime: add 24.22.29735.21

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index 72347c0ab415..9965624978b1 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-24.17.29377.6.tar.gz 7038804 BLAKE2B feb09b6627b5dbd376a88705fca61514e5f60aa2014617a591451f0be493dedc87e228f8599fd2e2488623fcc827d831f4294fa4b34375a75e17438b76d4fd97 SHA512 9cda876ebdff1a17cb495f95b637c8aac82dc58433da67d1f312b74dd423ca9f536dcbd10454f1e0702e3181b4f5d4eeb2d31d6d99a756749321b128cf1e9cc2
+DIST intel-compute-runtime-24.22.29735.21.tar.gz 7083856 BLAKE2B dbb31259b3a4305e42d4dce685ce3f98b3b308451d2b1061c6fcba5cc2b2aaf6862eaa326619f8b073478c64fc45994adc261583c0070464b027fda46028afa5 SHA512 64cbfdab69c595c118e37526be744bad95cf11e1c9de34aaec308cead5346d802e98e67f155da03fd174e51e7f78a38b3b6f48ba6e004f3181b533c8d31e851e
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-24.22.29735.21.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.22.29735.21.ebuild
new file mode 100644
index 000000000000..e227bc0c7d57
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.22.29735.21.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND="
+	>=dev-util/intel-graphics-compiler-1.0.17193.2
+	>=media-libs/gmmlib-22.3.19:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-0.8.16:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.17.6:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}