Revert "dev-php/pecl-http: add 4.2.6"

This reverts commit a7ecf66e9b9b1c43b7692568fefde2a371d8bad9.

pecl-raphf needs porting and the dep doesn't seem to have been
updated in pecl-http for that either.

Bug: https://bugs.gentoo.org/945977
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 0 insertions, 67 deletions

diff --git a/dev-php/pecl-http/pecl-http-4.2.6.ebuild b/dev-php/pecl-http/pecl-http-4.2.6.ebuild
deleted file mode 100644
index 8a95f7e8795f..000000000000
--- a/dev-php/pecl-http/pecl-http-4.2.6.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="8"
-
-PHP_EXT_NAME="http"
-PHP_EXT_PECL_PKG="pecl_http"
-PHP_EXT_INI="yes"
-PHP_EXT_ZENDEXT="no"
-PHP_INI_NAME="50-http"
-
-USE_PHP="php8-1 php8-2 php8-3"
-
-inherit php-ext-pecl-r3
-
-KEYWORDS="~amd64 ~x86"
-
-DESCRIPTION="Extended HTTP Support for PHP"
-LICENSE="BSD-2 MIT"
-SLOT="8"
-IUSE="ssl curl_ssl_gnutls +curl_ssl_openssl"
-
-COMMON_DEPEND="app-arch/brotli:=
-	dev-libs/libevent
-	>=dev-php/pecl-raphf-2.0.1:7[php_targets_php8-1(-)?]
-	net-dns/libidn2
-	sys-libs/zlib
-	ssl? ( net-misc/curl[ssl,curl_ssl_gnutls(-)=,curl_ssl_openssl(-)=] )
-	!ssl? ( net-misc/curl[-ssl] )
-"
-DEPEND="
-	php_targets_php8-1? ( ${COMMON_DEPEND} dev-lang/php:8.1[session(-),iconv(-)] )
-	php_targets_php8-2? ( ${COMMON_DEPEND} dev-lang/php:8.2[session(-),iconv(-)] )
-	php_targets_php8-3? ( ${COMMON_DEPEND} dev-lang/php:8.3[session(-),iconv(-)] )"
-RDEPEND="${DEPEND}"
-
-PHP_EXT_ECONF_ARGS=( --with-http --without-http-shared-deps
-	--without-http-libidn-dir  --without-http-libicu-dir
-	--without-http-libidnkit2-dir --without-http-libidnkit-dir )
-
-src_prepare() {
-	php-ext-source-r3_src_prepare
-
-	# Respect LDFLAGS, bug 727134
-	export EXTRA_LDFLAGS="${LDFLAGS}"
-}
-
-src_test() {
-	# Cannot use eclass function due to required modules
-	# All tests SKIP otherwise
-	local slot
-	for slot in $(php_get_slots); do
-		php_init_slot_env "${slot}"
-
-		# Link in required modules for testing
-		ln -s "${EXT_DIR}/raphf.so" "modules/raphf.so" || die
-
-		sed -i \
-			's/PHP_TEST_SHARED_EXTENSIONS)/PHP_TEST_SHARED_EXTENSIONS) -d extension=raphf/' \
-			Makefile || die
-
-		SKIP_ONLINE_TESTS=yes NO_INTERACTION="yes" emake test
-
-		# Clean up testing links
-		rm modules/raphf.so || die
-	done
-}