dev-python/PyGithub: Bump to 1.44.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/PyGithub/PyGithub-1.44.1.ebuild b/dev-python/PyGithub/PyGithub-1.44.1.ebuild
new file mode 100644
index 000000000000..385efd59ba3e
--- /dev/null
+++ b/dev-python/PyGithub/PyGithub-1.44.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to access the Github API v3"
+HOMEPAGE="https://github.com/PyGithub/PyGithub/"
+# Use github since pypi is missing test data
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/deprecated[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/httpretty-0.9.6[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+	)"
+
+python_prepare_all() {
+	# tests requiring network access
+	sed -i -e 's:testDecodeJson:_&:' tests/Issue142.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest -v tests.AllTests || die "Tests fail with ${EPYTHON}"
+}