dev-python/anyio: Bump to 4.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-python/anyio/anyio-4.0.0.ebuild b/dev-python/anyio/anyio-4.0.0.ebuild
new file mode 100644
index 000000000000..74d0dbd87994
--- /dev/null
+++ b/dev-python/anyio/anyio-4.0.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Compatibility layer for multiple asynchronous event loop implementations"
+HOMEPAGE="
+	https://github.com/agronholm/anyio/
+	https://pypi.org/project/anyio/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.2[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/idna-2.8[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.1[${PYTHON_USEDEP}]
+"
+# On amd64, let's get more test coverage by dragging in uvloop, but let's
+# not bother on other arches where uvloop may not be supported.
+BDEPEND="
+	>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.22[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		amd64? (
+			$(python_gen_cond_dep '
+				>=dev-python/uvloop-0.17[${PYTHON_USEDEP}]
+			' python3_{10..11})
+		)
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'>=dev-python/sphinx-rtd-theme-1.2.2' \
+	dev-python/sphinxcontrib-jquery \
+	dev-python/sphinx-autodoc-typehints
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires link-local IPv6 interface
+		tests/test_sockets.py::TestTCPListener::test_bind_link_local
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m 'not network'
+}