dev-python/async_timeout: Bump to version 2.0.1

Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Zac Medico <zmedico@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/async_timeout/async_timeout-2.0.1.ebuild b/dev-python/async_timeout/async_timeout-2.0.1.ebuild
new file mode 100644
index 000000000000..e4b133bd0a38
--- /dev/null
+++ b/dev-python/async_timeout/async_timeout-2.0.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit distutils-r1
+
+MY_P=${PN/_/-}-${PV}
+DESCRIPTION="Timeout context manager for asyncio programs"
+HOMEPAGE="https://github.com/aio-libs/async-timeout"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+S=${WORKDIR}/${MY_P}
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		<dev-python/pytest-aiohttp-0.3[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# remove pointless dep on pytest-cov
+	sed -i -e '/addopts/d' setup.cfg || die
+	# tests fail due to missing fixture when trying to load this file
+	rm tests/conftest.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}