dev-python/backports-unittest-mock: bump to 1.3

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/backports-unittest-mock/backports-unittest-mock-1.3.ebuild b/dev-python/backports-unittest-mock/backports-unittest-mock-1.3.ebuild
new file mode 100644
index 000000000000..3b613dc9cf56
--- /dev/null
+++ b/dev-python/backports-unittest-mock/backports-unittest-mock-1.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# It is the developer's intention that backports.unittest_mock will be
+# used even for Python 3: https://github.com/jaraco/jaraco.timing/pull/1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy{,3} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_PN="${MY_PN//-/_}"
+DESCRIPTION="Backport of unittest.mock"
+HOMEPAGE="https://github.com/jaraco/backports.unittest_mock"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/jaraco-packaging[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	py.test -v || die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	# avoid a collision with dev-python/backports
+	rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+	distutils-r1_python_install --skip-build
+}