dev-python/backports-zstd: New package, v1.0.0

Yet another zstd implementation for Python, this time backporting
the support from Python 3.14.  Surely this won't lead to XKCD#927.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/backports-zstd/backports-zstd-1.0.0.ebuild b/dev-python/backports-zstd/backports-zstd-1.0.0.ebuild
new file mode 100644
index 000000000000..f94e1528850d
--- /dev/null
+++ b/dev-python/backports-zstd/backports-zstd-1.0.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN/-/.}
+PYPI_VERIFY_REPO=https://github.com/Rogdham/backports.zstd
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Backport of PEP-784: adding Zstandard to the standard library"
+HOMEPAGE="
+	https://github.com/Rogdham/backports.zstd/
+	https://pypi.org/project/backports.zstd/
+"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	local PATCHES=(
+		# https://github.com/Rogdham/backports.zstd/pull/54
+		"${FILESDIR}/${P}-py313.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# remove -flto and other forced cflags
+	sed -i -e 's:kwargs\["extra.*:pass:' setup.py || die
+
+	DISTUTILS_ARGS=(
+		--system-zstd
+	)
+}
+
+python_test() {
+	eunittest tests
+}