dev-python/clang-python: Bump to 16.0.0_pre20221006

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/clang-python/clang-python-16.0.0_pre20221006.ebuild b/dev-python/clang-python/clang-python-16.0.0_pre20221006.ebuild
new file mode 100644
index 000000000000..f0290ca4c7b1
--- /dev/null
+++ b/dev-python/clang-python/clang-python-16.0.0_pre20221006.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		sys-devel/clang:${PV%%.*}
+	)
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	# tests rely on results from a specific clang version, so override
+	# the search path
+	local -x CLANG_LIBRARY_PATH=${BROOT}/usr/lib/llvm/${PV%%.*}/$(get_libdir)
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}