dev-python/python-distutils-extra: bump to 2.42, support python3.7

Also bumped to EAPI=7 and changed SRC_URI, as location has changed.

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Conrad Kostecki <conrad@kostecki.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/python-distutils-extra/python-distutils-extra-2.42.ebuild b/dev-python/python-distutils-extra/python-distutils-extra-2.42.ebuild
new file mode 100644
index 000000000000..3b3e02753ac1
--- /dev/null
+++ b/dev-python/python-distutils-extra/python-distutils-extra-2.42.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Gettext support, themed icons and scrollkeeper-based documentation in distutils"
+HOMEPAGE="https://launchpad.net/python-distutils-extra"
+SRC_URI="mirror://ubuntu/pool/universe/p/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="test"
+
+DEPEND="test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+DOCS=( doc/{README,FAQ} )
+
+python_prepare_all() {
+	# This line is run when the file is imported
+	# https://bugs.launchpad.net/python-distutils-extra/+bug/1657919
+	sed -i '/^unittest.main()$/d' test/auto.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# 5 tests fail with disabled byte-compilation (they rely on exact
+	# output from python).
+	# The other 4 are broken.
+	pytest -vv -k "not (test_pot_manual or test_pot_auto_explicit or \
+		test_pot_auto or test_modules or test_packages) and not \
+		(test_desktop or test_po or test_policykit or \
+		test_requires_provides)" test/auto.py || \
+		die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	docinto examples
+	dodoc doc/{setup.cfg.example,setup.py.example}
+	docompress -x /usr/share/doc/${PF}/examples
+}