dev-python/python-dotenv: 0.21.1

Signed-off-by: Sebastian Pipping <sping@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-python/python-dotenv/python-dotenv-0.21.1.ebuild b/dev-python/python-dotenv/python-dotenv-0.21.1.ebuild
new file mode 100644
index 000000000000..4a29583d56a1
--- /dev/null
+++ b/dev-python/python-dotenv/python-dotenv-0.21.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Manage .env files"
+HOMEPAGE="https://github.com/theskumar/python-dotenv"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	test? (
+		>=dev-python/click-5[${PYTHON_USEDEP}]
+		>=dev-python/sh-1.09[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+distutils_enable_tests pytest
+
+python_install() {
+	distutils-r1_python_install
+	ln -s dotenv "${D}$(python_get_scriptdir)"/python-dotenv || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Avoid collision with dev-ruby/dotenv (bug #798648)
+	mv "${ED}"/usr/bin/{,python-}dotenv || die
+}