dev-python/redis-py: Bump to 4.4.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/redis-py/Manifest b/dev-python/redis-py/Manifest
index 2ef1e6457b14..c7dfc3ab7862 100644
--- a/dev-python/redis-py/Manifest
+++ b/dev-python/redis-py/Manifest
@@ -1,2 +1,3 @@
 DIST redis-py-4.3.4.gh.tar.gz 4613714 BLAKE2B cea5a6455160c67c9ab3b8f9de8ae47aed97e7bea1e408ce1a001afe3e0c4a7a14220887504fa40c749d15be9d89f77e36b6f7a785e0ff22a49037b6ef245e87 SHA512 55dd00c15cedb82cb5edd46b1f18f32c0accb8c85b1b94bbfe04591dc07f6151ced81cbfca8ac6fe88a6743bf5abc50309ea23bef96bf4332a712979c61ea0b7
 DIST redis-py-4.3.5.gh.tar.gz 4620696 BLAKE2B 2eaa40fc0ad624c4b8444054dcfea70ba1a2a54aaa54954f0c0fab31b310d67ca25e7508bc3550a0033139bb36bb63ddea97bb807c91ca92df3630a5385d6ba5 SHA512 42ef903f07b818061aeaea5d7d188e058db1ef73275b731cfff762fb59cb91db708ad81b0b2773cf6e0ef200ecbb3bf9859f51c4fbeb04023547b9eac4e2e042
+DIST redis-py-4.4.0.gh.tar.gz 4637656 BLAKE2B 40b0909c27cefb399353cc2d1d82d7ad3d64e4b3e5ae001ffef9c198d0e65d906f5772a0ac33b599c7fb6ffc5dfad461bb4b9042c5c4fb23dfbfceb0a7facbc0 SHA512 8992f160de7817c48893f3a8588d5c0398dcfb91830a61b4218206adc88185acb102b072507d3064b4a7aade5c957267e5d0e6912510bb106eea834cf9250fab
diff --git a/dev-python/redis-py/redis-py-4.4.0.ebuild b/dev-python/redis-py/redis-py-4.4.0.ebuild
new file mode 100644
index 000000000000..928539d1ddbb
--- /dev/null
+++ b/dev-python/redis-py/redis-py-4.4.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Redis key-value store"
+HOMEPAGE="
+	https://github.com/redis/redis-py/
+	https://pypi.org/project/redis/
+"
+SRC_URI="
+	https://github.com/redis/redis-py/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async-timeout-4.0.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		<dev-db/redis-7
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Flaky test
+		tests/test_pubsub.py::TestPubSubDeadlock::test_pubsub_deadlock
+		# TODO
+		tests/test_commands.py::TestRedisCommands::test_acl_list
+	)
+
+	# TODO: try to run more servers?
+	epytest -m "not redismod and not onlycluster and not replica and not ssl"
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	# "${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start redis server"
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}