dev-python/twine: Bump to 6.0.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index 2e03c89e4caf..837c2a59ec76 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-5.1.1.gh.tar.gz 221931 BLAKE2B a95d50e52bde5db64c6ce5b57097188e9cb88763c91f337c3e552ca34bae34882d87bced4b0c55a292de185fce10384edf514b55373c4456ff252471076bcb28 SHA512 95f059235e32134a5320c0835befa2eed6eff35c56685afe4848224042c2e2af484db72f20fd0cfbe979cce8d495e8bb2d2ea38aca2c53ca7af8de378816bedf
+DIST twine-6.0.1.gh.tar.gz 223827 BLAKE2B ab88eb21908954ee7c32744ae9f7ccd7d50cb2b5207917144ef559e142837c89625596dea2c1bb0be21858bb0967690df999bb8a123e01beb5637a025dc490f9 SHA512 4fa7727d0728da3e05eaca068bf1dd85656225dd61958666ec0747359ee6bd88b25fd443d6c77bd8db245e71418cf8e5b594a6559ac1ecaafe3c079ecaefadba
diff --git a/dev-python/twine/twine-6.0.1.ebuild b/dev-python/twine/twine-6.0.1.ebuild
new file mode 100644
index 000000000000..5c1d9c150e09
--- /dev/null
+++ b/dev-python/twine/twine-6.0.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/keyring-15.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/readme-renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.0.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+	sed -i -e '/--cov/d' pytest.ini || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# Avoid needing heavy virtualx
+		tests/test_auth.py::test_warns_for_empty_password
+	)
+
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}