dev-ruby/actionmailbox: add 8.1.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-ruby/actionmailbox/actionmailbox-8.1.0.ebuild b/dev-ruby/actionmailbox/actionmailbox-8.1.0.ebuild
new file mode 100644
index 000000000000..10a4f3f04122
--- /dev/null
+++ b/dev-ruby/actionmailbox/actionmailbox-8.1.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="actionmailbox.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_EXTRAINSTALL="app config db"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Framework for designing email-service layers"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/actionpack-${PV}
+	~dev-ruby/activejob-${PV}
+	~dev-ruby/activerecord-${PV}
+	~dev-ruby/activestorage-${PV}
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/mail-2.8.0:*
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/bundler
+	dev-ruby/minitest:5
+	dev-ruby/mocha
+	dev-ruby/propshaft
+	dev-ruby/rexml
+	>=dev-ruby/sqlite3-2.1
+	dev-ruby/webmock
+	dev-ruby/rails
+)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|mysql2\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|sass-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|sprockets\|stackprof\|websocket-client-simple\|libxml-ruby\|redis\|blade\|aws-sdk\|google-cloud\|azure-storage\|selenium\|webdrivers\|webrick\|minitest-bisect\|minitest-retry\|minitest-reporters\|listen\|rack-cache\|rack-test\|capybara\|webpacker\|bootsnap\|dalli\|connection_pool\|terser\|cookiejar\|cgi\|web-console\|trilogy\|error_highlight\|jbuilder\|httpclient\|prism\|solid\|kamal\|thruster\|releaser\)/ s:^:#:" \
+		-e '/stimulus-rails/,/tailwindcss-rails/ s:^:#:' \
+		-e '/group :\(cable\|doc\|job\|lint\|mdl\|rubocop\|storage\|test\)/,/^end/ s:^:#:' \
+		-i ../Gemfile || die
+	rm ../Gemfile.lock || die
+	sed -i -e '/byebug/ s:^:#:' test/test_helper.rb || die
+}
+
+each_ruby_prepare() {
+	sed -i -e 's:ruby:'${RUBY}':' test/dummy/bin/* || die
+}