dev-ruby/async: add 2.25.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/async/async-2.25.0.ebuild b/dev-ruby/async/async-2.25.0.ebuild
new file mode 100644
index 000000000000..8ac8846b77bf
--- /dev/null
+++ b/dev-ruby/async/async-2.25.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_RECIPE_TEST="sus"
+RUBY_FAKEGEM_EXTRADOC="readme.md"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A concurrency framework for Ruby"
+HOMEPAGE="https://github.com/socketry/async"
+SRC_URI="https://github.com/socketry/async/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~riscv ~sparc ~x86"
+
+ruby_add_rdepend "
+	>=dev-ruby/console-1.29:1
+	dev-ruby/fiber-annotation
+	>=dev-ruby/io-event-1.11:1
+	>=dev-ruby/metrics-0.12:0
+	>=dev-ruby/traces-0.15:0
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/benchmark-ips
+	dev-ruby/sus-fixtures-async
+	dev-ruby/sus-fixtures-console
+	dev-ruby/sus-fixtures-time
+)"
+
+all_ruby_prepare() {
+	sed -i -E 's/require_relative "(.+)"/require File.expand_path("\1")/g' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# network tests
+	rm test/net/http.rb \
+		test/async/scheduler/address.rb \
+		test/async/scheduler/io.rb || die
+
+	# Remove developer-only test configuration
+	rm -f config/sus.rb || die
+}