2 files changed, 81 insertions, 0 deletions
diff --git a/dev-vcs/git-cola/Manifest b/dev-vcs/git-cola/Manifest
index 11fbf91bb9b2..2256f5d3411b 100644
--- a/dev-vcs/git-cola/Manifest
+++ b/dev-vcs/git-cola/Manifest
@@ -1 +1,2 @@
 DIST git-cola-4.13.0.tar.gz 1276304 BLAKE2B 2e75241ed1c528478199aa9977776ceafc8ba72c5b674bc69aceaceb44b1b44db138ac98ea4441100f586dd0940ffcf18b9b64d70a464cbe957d40fe7878dcca SHA512 57b74cf98b6ec72946d730a5e59fbe4e57edaefa7b935a1d757e43e4faea6bc5d1752fbf37767250120d7192cb131c6565b6577e1857c3c6ad48ab6518f21316
+DIST git-cola-4.14.0.tar.gz 1338074 BLAKE2B b6371bd91700f4702e063314bf28f834c3749d2041f0e65598af5e4beb4fcb905f3cd375c957a05f4a4b9fd463f732645ff644ef38ab097d12726512ef300468 SHA512 9b5cc0039cf6b47fe4524f1b672681ea2c0a3883e7761096256291b0ddb485df02b50bc35e7329edb4d3346841195f07f50123aadc2fa1e41196c5795e4f3011
diff --git a/dev-vcs/git-cola/git-cola-4.14.0.ebuild b/dev-vcs/git-cola/git-cola-4.14.0.ebuild
new file mode 100644
index 000000000000..c052fd0a6ae3
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-4.14.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+DISTUTILS_SINGLE_IMPL=true
+DISTUTILS_USE_PEP517=setuptools
+inherit desktop distutils-r1 optfeature readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="https://git-cola.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/polib[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/qtpy[pyqt6,gui,network,${PYTHON_USEDEP}]
+	')
+	dev-vcs/git
+"
+BDEPEND="
+	sys-devel/gettext
+	$(python_gen_cond_dep "
+		dev-python/setuptools-scm[\${PYTHON_USEDEP}]
+		test? (
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/qtpy[pyqt6,gui,network,\${PYTHON_USEDEP}]
+		)
+	")
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/rst-linker'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove bundled qtpy and polib
+	rm -Rf qtpy cola/polib.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	cd "${T}" || die
+	GIT_CONFIG_NOSYSTEM=true LC_ALL="C.utf8" \
+	epytest "${S}"/test
+}
+
+src_compile() {
+	SETUPTOOLS_SCM_PRETEND_VERSION=${PV} distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	domenu share/applications/*.desktop
+	doicon -s scalable cola/icons/git-cola.svg
+
+	# patch the binaries to use desired qtpy backend
+	sed -i "s|import sys|import sys\nimport os\nos.environ['QT_API'] = 'pyqt6'\n|" "${D}"/usr/bin/* || die
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "enable desktop notifications" dev-python/notify2
+	optfeature "enables Send to Trash feature" dev-python/send2trash
+}