1 files changed, 53 insertions, 0 deletions
diff --git a/dev-ada/gnatmem/gnatmem-2021-r6.ebuild b/dev-ada/gnatmem/gnatmem-2021-r6.ebuild
new file mode 100644
index 000000000000..e6b98054ed64
--- /dev/null
+++ b/dev-ada/gnatmem/gnatmem-2021-r6.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ADA_COMPAT=( gcc_{12..16} )
+inherit ada multiprocessing autotools
+
+MYP=${P}-${PV}0518-19F7B-src
+ID=3ddb98c0c8854dc7631bebd673ac7bc53038d4b7
+ADAMIRROR=https://community.download.adacore.com/v1
+
+DESCRIPTION="Monitors dynamic allocation and deallocation activity in a program"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="${ADAMIRROR}/${ID}?filename=${MYP}.tar.gz -> ${MYP}.tar.gz"
+
+S="${WORKDIR}"/${MYP}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+
+RDEPEND="
+	${ADA_DEPS}
+	sys-libs/binutils-libs:=
+"
+DEPEND="
+	${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]
+"
+
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2018-gentoo.patch
+)
+
+src_prepare() {
+	default
+	mv configure.in configure.ac
+	eautoreconf
+}
+
+src_compile() {
+	gprbuild -v -p -Pgnatmem.gpr -j$(makeopts_jobs) \
+		-cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} \
+		-largs ${LDFLAGS} \
+		|| die
+}
+
+src_install() {
+	dobin obj/gnatmem
+}