1 files changed, 62 insertions, 0 deletions
diff --git a/dev-cpp/gtest/gtest-1.6.0-r2.ebuild b/dev-cpp/gtest/gtest-1.6.0-r2.ebuild
new file mode 100644
index 000000000000..2c3a158088f4
--- /dev/null
+++ b/dev-cpp/gtest/gtest-1.6.0-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+# Python is required for tests and some build tasks.
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-any-r1 autotools-multilib
+
+DESCRIPTION="Google C++ Testing Framework"
+HOMEPAGE="http://code.google.com/p/googletest/"
+SRC_URI="http://googletest.googlecode.com/files/${P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="examples static-libs"
+
+DEPEND="app-arch/unzip
+	${PYTHON_DEPS}"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}/configure-fix-pthread-linking.patch" #371647
+)
+
+AUTOTOOLS_AUTORECONF="1"
+
+src_prepare() {
+	sed -i -e "s|/tmp|${T}|g" test/gtest-filepath_test.cc || die
+	sed -i -r \
+		-e '/^install-(data|exec)-local:/s|^.*$|&\ndisabled-&|' \
+		Makefile.am || die
+	autotools-multilib_src_prepare
+
+	multilib_copy_sources
+}
+
+src_configure() {
+	multilib_parallel_foreach_abi gtest_src_configure
+}
+
+src_install() {
+	autotools-multilib_src_install
+	multilib_for_best_abi gtest-config_install
+
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins samples/*.{cc,h}
+	fi
+}
+
+gtest_src_configure() {
+	ECONF_SOURCE="${BUILD_DIR}"
+	autotools-utils_src_configure
+}
+
+gtest-config_install() {
+	dobin "${BUILD_DIR}/scripts/gtest-config"
+}