2 files changed, 61 insertions, 0 deletions
diff --git a/dev-lang/moarvm/Manifest b/dev-lang/moarvm/Manifest
index 4e71e7c18faa..a65e5aa2e40a 100644
--- a/dev-lang/moarvm/Manifest
+++ b/dev-lang/moarvm/Manifest
@@ -1,2 +1,3 @@
 DIST MoarVM-2025.01.tar.gz 15014714 BLAKE2B 5e407cbd9d33d9934a198e0c4c9baeeee71bf4270c2339edf681cb46393e2542f947fd789ca9f07422be34adfcb1f15834c838054161825de5511ea477c8df1d SHA512 1107e9eda080c0b68fff181fd712c6d2bd03c1f06b46b88d7d99feb6457a7d1e0b6c138bae404faf240b2642a701d6ced399e7d0b0949d691089d2264f58bfa3
 DIST MoarVM-2025.05.tar.gz 15114902 BLAKE2B b9983bbe517595925e370d69ad3b71ebc509f659d9838ac9292adb60272c811d3bc85552b4e4cfa615ddf2346e4efc2e296159b461a8f73e21a6f3e4aff96cd1 SHA512 e3b30a082a39c4c0128fe59d86b9e86888590aa1941b5bb25a8441dc1fa8b5e0d66fcae87f877141183c1eb4c0efc8218dce883314794c32fe0e4adbfde7ed62
+DIST MoarVM-2025.06.tar.gz 15247194 BLAKE2B 626b70df4728e18a522424b60bc12160b5f5f3edf31669131f84e7d48686cf8d31d058832cd3350592deb2e0fc682646b44a13827e161847a47391fa77441541 SHA512 8c60dbfa433a1660dbdc72b443df63e5dc9503a687df5d2fed492a4c2fb2df614f17c947109c8fa2d17b7520298574e299559a251de2bcc33ebc2fb41f1c6c8b
diff --git a/dev-lang/moarvm/moarvm-2025.06.ebuild b/dev-lang/moarvm/moarvm-2025.06.ebuild
new file mode 100644
index 000000000000..be57ae8eb669
--- /dev/null
+++ b/dev-lang/moarvm/moarvm-2025.06.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="MoarVM"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/${MY_PN}/${MY_PN}.git"
+	inherit git-r3
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="http://moarvm.org/releases/${MY_PN}-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="A 6model-based VM for NQP and Raku"
+HOMEPAGE="http://moarvm.org"
+LICENSE="Artistic-2"
+SLOT="0"
+
+IUSE="asan clang debug doc +jit optimize static-libs ubsan"
+
+RDEPEND="dev-libs/libatomic_ops
+	>=dev-libs/libuv-1.26:=
+	dev-libs/libffi:=
+	dev-libs/mimalloc"
+DEPEND="${RDEPEND}
+	clang? ( llvm-core/clang )
+	dev-lang/perl"
+
+DOCS=( CREDITS README.md )
+
+# Tests are conducted via nqp
+RESTRICT=test
+
+src_configure() {
+	MAKEOPTS+=" NOISY=1"
+	use doc && DOCS+=( docs/* )
+	local prefix="${EPREFIX}/usr"
+	local libdir="${EPREFIX}/usr/$(get_libdir)"
+	einfo "--prefix '${prefix}'"
+	einfo "--libdir '${libdir}'"
+	local myconfigargs=(
+		"--prefix" "${prefix}"
+		"--has-libuv"
+		"--has-libatomic_ops"
+		"--has-libffi"
+		"--has-mimalloc"
+		"--libdir" "${libdir}"
+		"--compiler" "$(usex clang clang gcc)"
+		"$(usex asan        --asan)"
+		"$(usex debug       --debug            --no-debug)"
+		"$(usex optimize    --optimize=        --no-optimize)"
+		"$(usex static-libs --static)"
+		"$(usex ubsan       --ubsan)"
+	)
+
+	perl Configure.pl "${myconfigargs[@]}" moarshared || die
+}