1 files changed, 54 insertions, 0 deletions
diff --git a/dev-lua/luassert/luassert-1.9.0.ebuild b/dev-lua/luassert/luassert-1.9.0.ebuild
new file mode 100644
index 000000000000..3bfe540696f0
--- /dev/null
+++ b/dev-lua/luassert/luassert-1.9.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua
+
+DESCRIPTION="Assertion library for Lua"
+HOMEPAGE="http://olivinelabs.com/busted/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-lua/say[${LUA_USEDEP}]
+	${LUA_DEPS}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-lua/busted[${LUA_USEDEP}]
+		dev-lua/lua_cliargs[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)/luassert
+	doins -r src/.
+
+	einstalldocs
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}