2 files changed, 70 insertions, 0 deletions
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 3bae31cb03e4..2bfd7bcb3063 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1 +1,2 @@
 DIST pydantic-2.11.7.tar.gz 788350 BLAKE2B 4767f593beb649fe3139f3b22e3814a9f56793494dc17428cf70952451e9112d03b275c0af979f0f0159b25deae2e2794bfdb1392e2c3499220ad3cd67945414 SHA512 54ee1a49d5a429cad31928425c197139ae3cce004d8f3530835ce39897be9afa6aea35e639af1d6290bace7148e1369ce66840e26bced329bc2e7d93b3dad6e5
+DIST pydantic-2.12.0a1.tar.gz 802751 BLAKE2B e0e8a9ed89a7cb3a8a8d4f09e81965a98ceb9d68a74fc6c60417d49fc9f86f7e99077f7209a737d8c8defadc2fa7312b83dbae1ecb8781d6595b4a5f48f66941 SHA512 ce78aee6ebe98eb40ebde832e82e75688e82bd9b2d703ef8d86044ae904d1760ad920d7d4c9b2efe2e61d9e476499c9c038ffd3dfc3ee9a1b3218a84d94dad30
diff --git a/dev-python/pydantic/pydantic-2.12.0_alpha1.ebuild b/dev-python/pydantic/pydantic-2.12.0_alpha1.ebuild
new file mode 100644
index 000000000000..07b54c5cd78f
--- /dev/null
+++ b/dev-python/pydantic/pydantic-2.12.0_alpha1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic/
+	https://pypi.org/project/pydantic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/annotated-types-0.6.0[${PYTHON_USEDEP}]
+	~dev-python/pydantic-core-2.37.2[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.14.1[${PYTHON_USEDEP}]
+	>=dev-python/typing-inspection-0.4.0[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/cloudpickle[${PYTHON_USEDEP}]
+		' 'python3*')
+		dev-python/dirty-equals[${PYTHON_USEDEP}]
+		>=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/faker-18.13.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/benchmark/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# -Werror, sigh
+		tests/test_types_typeddict.py::test_readonly_qualifier_warning
+	)
+	local EPYTEST_IGNORE=(
+		# require pytest-examples
+		tests/test_docs.py
+		# benchmarks
+		tests/benchmarks
+	)
+
+	if ! has_version "dev-python/cloudpickle[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/test_pickle.py
+		)
+	fi
+
+	epytest
+}