1 files changed, 49 insertions, 0 deletions
diff --git a/dev-ruby/activemodel/activemodel-4.0.13.ebuild b/dev-ruby/activemodel/activemodel-4.0.13.ebuild
new file mode 100644
index 000000000000..50b7056bf2b3
--- /dev/null
+++ b/dev-ruby/activemodel/activemodel-4.0.13.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby19 ruby20 ruby21"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="activemodel.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="A toolkit for building modeling frameworks like Active Record and Active Resource"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	>=dev-ruby/builder-3.1.0:3.1
+	>=dev-ruby/bcrypt-ruby-3.1.7"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/bundler
+		>=dev-ruby/railties-4.0.0
+		dev-ruby/test-unit:2
+		>=dev-ruby/mocha-0.13.0:0.13
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(uglifier\|system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|'mysql'\|journey\|ruby-prof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|redcarpet\)/d" ../Gemfile || die
+	sed -i -e '/rack-ssl/d' -e 's/~> 3.4/>= 3.4/' ../railties/railties.gemspec || die
+
+	# Fix bcrypt dependency since bcrypt uses semantic versioning.
+	sed -i -e '/bcrypt-ruby/ s/3.0.0/3.0/' lib/active_model/secure_password.rb || die
+}