summaryrefslogtreecommitdiff
path: root/net-libs
diff options
context:
space:
mode:
Diffstat (limited to 'net-libs')
-rw-r--r--net-libs/cppzmq/Manifest1
-rw-r--r--net-libs/cppzmq/cppzmq-4.10.0.ebuild4
-rw-r--r--net-libs/cppzmq/cppzmq-4.11.0.ebuild37
-rw-r--r--net-libs/cppzmq/cppzmq-4.9.0.ebuild4
-rw-r--r--net-libs/czmq/czmq-4.2.1.ebuild8
-rw-r--r--net-libs/libktorrent/Manifest1
-rw-r--r--net-libs/libktorrent/libktorrent-25.12.0.ebuild65
-rw-r--r--net-libs/msgraph/msgraph-0.2.3.ebuild8
-rw-r--r--net-libs/nodejs/Manifest1
-rw-r--r--net-libs/nodejs/nodejs-20.19.6.ebuild274
-rw-r--r--net-libs/tdlib/Manifest2
-rw-r--r--net-libs/tdlib/tdlib-1.8.49_p20250510-r1.ebuild (renamed from net-libs/tdlib/tdlib-1.8.49_p20250510.ebuild)2
-rw-r--r--net-libs/tdlib/tdlib-1.8.58.ebuild (renamed from net-libs/tdlib/tdlib-1.8.55.ebuild)4
13 files changed, 398 insertions, 13 deletions
diff --git a/net-libs/cppzmq/Manifest b/net-libs/cppzmq/Manifest
index 8f84067a5cb4..6240e610409d 100644
--- a/net-libs/cppzmq/Manifest
+++ b/net-libs/cppzmq/Manifest
@@ -1,2 +1,3 @@
DIST cppzmq-4.10.0.tar.gz 47099 BLAKE2B 7c85b95f45901b21a4f66c109427ac383494d58c27e54db7f56cc53b913ae154caa2f51c538c1e80f5479181ff83c9a1b1a389c74f2fa6545de874299c8bbc5b SHA512 4a4f3c2a270b9b21591b08a81f2ab6a72693af213c115f2c0aa5b737fd0363d09dba92437f48268ff982e6c27d6830f79244599bd9198e3402c6cca566cea27a
+DIST cppzmq-4.11.0.tar.gz 49666 BLAKE2B bc2569c2260cfc08a81f0a14b42e81911dd338ab496dd09ba681a908ca7df427ee6656a825133045271318a0fb4b79bc1513f5d7195da558ab6fe6e9cf633304 SHA512 7ef3866fe0a337771be40153dd744306fa951214329670a068a0344e909b1128fabce22676561d68bed270716e6fabda53e8bcc839184565db634b38d11bdbac
DIST cppzmq-4.9.0.tar.gz 46936 BLAKE2B 230c5a983fb902bdf880b1b0464033a389c500cae635b501275cc3df0980765bd48c1e1a1bb4e1a3d49b1fe63648d77feebc39a7f35c0474bfdc7e2e918c920f SHA512 a9d1c25084b5b84dfa20a005299213c3bb610e46ac7433236fd8d3c60c7e71153c738da4645343080c0d1cad9008aca1a3091d4247c7a2f08c506ed3054d55a7
diff --git a/net-libs/cppzmq/cppzmq-4.10.0.ebuild b/net-libs/cppzmq/cppzmq-4.10.0.ebuild
index 4fb02db8a148..21f81e94f89b 100644
--- a/net-libs/cppzmq/cppzmq-4.10.0.ebuild
+++ b/net-libs/cppzmq/cppzmq-4.10.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@@ -9,8 +9,8 @@ DESCRIPTION="High-level CPP Binding for ZeroMQ"
HOMEPAGE="https://github.com/zeromq/cppzmq"
SRC_URI="https://github.com/zeromq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-SLOT="0"
LICENSE="MIT"
+SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~riscv x86 ~x86-linux"
IUSE="test"
diff --git a/net-libs/cppzmq/cppzmq-4.11.0.ebuild b/net-libs/cppzmq/cppzmq-4.11.0.ebuild
new file mode 100644
index 000000000000..902b3eee1e30
--- /dev/null
+++ b/net-libs/cppzmq/cppzmq-4.11.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="High-level CPP Binding for ZeroMQ"
+HOMEPAGE="https://github.com/zeromq/cppzmq"
+SRC_URI="https://github.com/zeromq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~x86-linux"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=net-libs/zeromq-4.3.1"
+# Tests require cmake modules from catch2 and headers from older version of catch
+DEPEND="${RDEPEND}
+ test? ( =dev-cpp/catch-3* )"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-4.9.0-disable-static.patch"
+)
+
+src_configure() {
+ local mycmakeargs=(
+ -DCPPZMQ_CMAKECONFIG_INSTALL_DIR="/usr/$(get_libdir)/cmake/${PN}/"
+ -DCPPZMQ_BUILD_TESTS="$(usex test)"
+ )
+ if has_version -d '>=net-libs/zeromq-4.3.1[drafts]'; then
+ mycmakeargs+=( -DENABLE_DRAFTS=on )
+ fi
+ cmake_src_configure
+}
diff --git a/net-libs/cppzmq/cppzmq-4.9.0.ebuild b/net-libs/cppzmq/cppzmq-4.9.0.ebuild
index 2b4063863cad..52885b68923b 100644
--- a/net-libs/cppzmq/cppzmq-4.9.0.ebuild
+++ b/net-libs/cppzmq/cppzmq-4.9.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@@ -9,8 +9,8 @@ DESCRIPTION="High-level CPP Binding for ZeroMQ"
HOMEPAGE="https://github.com/zeromq/cppzmq"
SRC_URI="https://github.com/zeromq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-SLOT="0"
LICENSE="MIT"
+SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~riscv x86 ~x86-linux"
IUSE="test"
diff --git a/net-libs/czmq/czmq-4.2.1.ebuild b/net-libs/czmq/czmq-4.2.1.ebuild
index 39e39a7930ea..85a0fd50c9cb 100644
--- a/net-libs/czmq/czmq-4.2.1.ebuild
+++ b/net-libs/czmq/czmq-4.2.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
@@ -10,7 +10,7 @@ SRC_URI="https://github.com/zeromq/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="MPL-2.0"
SLOT="0/4"
KEYWORDS="amd64 arm arm64 ~hppa ~ppc64 ~riscv x86"
-IUSE="curl drafts http-client http-server lz4 nss static-libs systemd test +uuid"
+IUSE="curl drafts http-client http-server lz4 nss systemd test +uuid"
RESTRICT="!test? ( test )"
BDEPEND="app-text/asciidoc
@@ -54,7 +54,5 @@ src_configure() {
src_install() {
default
- if ! use static-libs ; then
- find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
- fi
+ find "${ED}" -type f -name "*.la" -delete || die
}
diff --git a/net-libs/libktorrent/Manifest b/net-libs/libktorrent/Manifest
index ce9c9c1b7bf5..aed084a877c4 100644
--- a/net-libs/libktorrent/Manifest
+++ b/net-libs/libktorrent/Manifest
@@ -1 +1,2 @@
DIST libktorrent-25.08.3.tar.xz 607156 BLAKE2B a1786b7fa68f990cfd5f5cbc9c0ddf54815c319052ed93c13f0a43ea8e31f4e3466e521567e0a91bb7a401cff24c1c16fc0c607c73580dc8dca8687552d8c161 SHA512 18cdac7194dcaab58568d844c48bd5ca21983bb99784f14f82d15aa620c24bfde27ef298e519cc5f5d2472fcba65288dc5458027faecf754a92b83e637404ae4
+DIST libktorrent-25.12.0.tar.xz 608520 BLAKE2B df68aa8af78bf8c09e2f78cff0549f28054771ef23aa9649f7ec82d732fe00942f6ed83a805f5fb3515eeba87def7b3d954b1ff50a083f4bc022d56926b51475 SHA512 433aefefa7852a744aa0482944a5b9214be6574b5e5cd57b43123794baf5ada3871d9f9bab9ef8a85b3926cad3910afb524afdec08166655579f9abb17d6dbc3
diff --git a/net-libs/libktorrent/libktorrent-25.12.0.ebuild b/net-libs/libktorrent/libktorrent-25.12.0.ebuild
new file mode 100644
index 000000000000..60f6b52334e6
--- /dev/null
+++ b/net-libs/libktorrent/libktorrent-25.12.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="network"
+KFMIN=6.19.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="xfs"
+
+COMMON_DEPEND="
+ >=dev-libs/gmp-6.0.0a:0=
+ >=dev-libs/openssl-3:0=
+ >=dev-qt/qtbase-${QTMIN}:6[network,xml]
+ >=kde-frameworks/karchive-${KFMIN}:6
+ >=kde-frameworks/kconfig-${KFMIN}:6
+ >=kde-frameworks/kcoreaddons-${KFMIN}:6
+ >=kde-frameworks/kcrash-${KFMIN}:6
+ >=kde-frameworks/ki18n-${KFMIN}:6
+ >=kde-frameworks/kio-${KFMIN}:6
+ >=kde-frameworks/solid-${KFMIN}:6
+ xfs? ( sys-fs/xfsprogs )
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+ !dev-libs/botan[gmp(-)]
+"
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+ ecm_src_prepare
+
+ # Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+ sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+ CMakeLists.txt || die
+ sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+ KTorrent6Config.cmake.in || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DUSE_CRYPTO_BACKEND=OpenSSL
+ -DWITH_XFS=$(usex xfs)
+ )
+ ecm_src_configure
+}
+
+src_test() {
+ # failing network tests
+ local myctestargs=(
+ -E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
+ )
+ ecm_src_test
+}
diff --git a/net-libs/msgraph/msgraph-0.2.3.ebuild b/net-libs/msgraph/msgraph-0.2.3.ebuild
index 93f661c2f493..971a3c614797 100644
--- a/net-libs/msgraph/msgraph-0.2.3.ebuild
+++ b/net-libs/msgraph/msgraph-0.2.3.ebuild
@@ -45,3 +45,11 @@ src_configure() {
)
meson_src_configure
}
+
+src_install(){
+ meson_install
+ if use gtk-doc; then
+ mkdir -p "${ED}"/usr/share/gtk-doc/html || die
+ mv "${ED}"/usr/share/doc/msgraph-* "${ED}"/usr/share/gtk-doc/html || die
+ fi
+}
diff --git a/net-libs/nodejs/Manifest b/net-libs/nodejs/Manifest
index 6933b25a0f34..8a857f206177 100644
--- a/net-libs/nodejs/Manifest
+++ b/net-libs/nodejs/Manifest
@@ -1,6 +1,7 @@
DIST node-v20.18.2.tar.xz 41933624 BLAKE2B afe01b8df6f89254eca3b849a3603cba0eda809ba0ed37c0a401323f09402ef52be4b2b15e571fd1a876ec0b5168b46c72144f23fd30f4a96793c54ce37f4317 SHA512 c0b294a7dba42d1b898a552b66d6cdc6e5a55a2ef951f272e9614578c656d72bf727c9ebb39e27de671cfecc36bc8bf60330fb00285de012f256dbd69142868c
DIST node-v20.19.2.tar.xz 42289480 BLAKE2B b4a1611b8edd41ee8effd3bc2fb1e6d1f4e2b6f3c6a97d357cfdffab16042af49b0431860d66267d4cb6dd95c24e13c71f5c9015f1f59f611d2087713fe6c78d SHA512 fea753af76e45ad773fd26988dc6e6eb83cf4ee71f2c02eac0660ce40b823bb991ad70567502c54de8723fbeed68e7a81c15655dca2da4982cbe8391e76d97c8
DIST node-v20.19.5.tar.xz 42505652 BLAKE2B 952a7cd724a4a381aa109941557bb2b87063ca8a8fdc3ac6203aaccfb24376a7899d9098cefaded6f5f3be0cf4851a872fa6bfc14f9b9914ff35341063a45453 SHA512 b585222636b0ed05567f99dba3312586ac64d0a1a751a471305f10e85a77ad32ed6c4a30b2fc0a876f1e9b4f6880c1ccf596346605f5298d882396b3677efe0f
+DIST node-v20.19.6.tar.xz 42530628 BLAKE2B 7a0e5d469cc58cf744f2edc1421828dbcbe0171179152da732ecc8e1d2c6139d68f453b6c7ff11ac31079d12663306f02774819ab056cf49a3b9e22979d1807d SHA512 cf3a3813db814ffe23dd9c2c201b950522c4a115569d568cb3ef2f6b3f9a33cdd7d3f6d52f7d8970df6fadc0b8aa86dd2ef1fd34a4537cbdbe5d05363c47976d
DIST node-v22.13.1.tar.xz 48041964 BLAKE2B 9695cc6a9b9606a615cdcff42e9b8d5f15c2d12fd0f6c894596a7c6526b3267ab9ea4f7362f8c03039c728cb5f7a3a334cce7fda9293cba06922000542a2800c SHA512 711fbeacceec16b8808e5a41ead496347fee2304fc6ce095ad26c4413f52253c9f3a6cd78080e808c03c3dbe958d64359d2d6bb97a51e1b41e1cff903ce2aeb5
DIST node-v22.16.0.tar.xz 48547612 BLAKE2B 7c765ca665822d4e6412ab32d5aa152ecfd3643591a9584bfbcb4baf046cea7c0e42ee09102bb8106861bac86e936c63c3b5516922863ffae4cc2af5909b3c5b SHA512 8d33efd7d6e15b212d0a24483f751705935ab8a0124c695103e96cd806b8c76d4639ac53bd4abf09e3e636ff301eba3546ead447e5e881a51ca87a72ab26e004
DIST node-v22.19.0.tar.xz 48853616 BLAKE2B e024ec9f9b59ab71f809c51f01406c3eb01dfc411ea22f67d7881dadd6429e9db6e4fd7081bd8137441873d450457061165eb39fab4e5088e2daf5025c9328fd SHA512 aefce510b74c9c9cc4bf4e68be1a8916b2e79e0382fedf1da5ec597cde7fd225501e76d1f024287b3b2b1c12139cc8020fcc4d6e4e96fba31cd17106de77f56a
diff --git a/net-libs/nodejs/nodejs-20.19.6.ebuild b/net-libs/nodejs/nodejs-20.19.6.ebuild
new file mode 100644
index 000000000000..0d597c084899
--- /dev/null
+++ b/net-libs/nodejs/nodejs-20.19.6.ebuild
@@ -0,0 +1,274 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CONFIG_CHECK="~ADVISE_SYSCALLS"
+PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit bash-completion-r1 check-reqs flag-o-matic linux-info ninja-utils pax-utils python-any-r1 toolchain-funcs xdg-utils
+
+DESCRIPTION="A JavaScript runtime built on Chrome's V8 JavaScript engine"
+HOMEPAGE="https://nodejs.org/"
+LICENSE="Apache-1.1 Apache-2.0 BSD BSD-2 MIT"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/nodejs/node"
+ SLOT="0"
+else
+ SRC_URI="https://nodejs.org/dist/v${PV}/node-v${PV}.tar.xz"
+ SLOT="0/$(ver_cut 1)"
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x64-macos"
+ S="${WORKDIR}/node-v${PV}"
+fi
+
+IUSE="corepack cpu_flags_x86_sse2 debug doc +icu +inspector lto npm pax-kernel +snapshot +ssl +system-icu +system-ssl test"
+REQUIRED_USE="inspector? ( icu ssl )
+ npm? ( ssl )
+ system-icu? ( icu )
+ system-ssl? ( ssl )
+ x86? ( cpu_flags_x86_sse2 )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=app-arch/brotli-1.0.9:=
+ >=dev-libs/libuv-1.46.0:=
+ >=net-dns/c-ares-1.18.1:=
+ >=net-libs/nghttp2-1.41.0:=
+ >=net-libs/ngtcp2-1.1.0:=
+ virtual/zlib:=
+ corepack? ( !sys-apps/yarn )
+ system-icu? ( >=dev-libs/icu-73:= )
+ system-ssl? ( >=dev-libs/openssl-1.1.1:0= )
+ sys-devel/gcc:*"
+BDEPEND="${PYTHON_DEPS}
+ app-alternatives/ninja
+ sys-apps/coreutils
+ virtual/pkgconfig
+ test? ( net-misc/curl )
+ pax-kernel? ( sys-apps/elfix )"
+DEPEND="${RDEPEND}"
+
+# These are measured on a loong machine with -ggdb on, and only checked
+# if debugging flags are present in CFLAGS.
+#
+# The final link consumed a little more than 7GiB alone, so 8GiB is the lower
+# limit for memory usage. Disk usage was 19.1GiB for the build directory and
+# 1.2GiB for the installed image, so we leave some room for architectures with
+# fatter binaries and set the disk requirement to 22GiB.
+CHECKREQS_MEMORY="8G"
+CHECKREQS_DISK_BUILD="22G"
+
+pkg_pretend() {
+ if [[ ${MERGE_TYPE} != "binary" ]]; then
+ if is-flagq "-g*" && ! is-flagq "-g*0" ; then
+ einfo "Checking for sufficient disk space and memory to build ${PN} with debugging CFLAGS"
+ check-reqs_pkg_pretend
+ fi
+ fi
+}
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+ linux-info_pkg_setup
+}
+
+src_prepare() {
+ tc-export AR CC CXX PKG_CONFIG
+ export V=1
+ export BUILDTYPE=Release
+
+ # fix compilation on Darwin
+ # https://code.google.com/p/gyp/issues/detail?id=260
+ sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die
+
+ # proper libdir, hat tip @ryanpcmcquen https://github.com/iojs/io.js/issues/504
+ local LIBDIR=$(get_libdir)
+ sed -i -e "s|lib/|${LIBDIR}/|g" tools/install.py || die
+ sed -i -e "s/'lib'/'${LIBDIR}'/" deps/npm/lib/npm.js || die
+
+ # Avoid writing a depfile, not useful
+ sed -i -e "/DEPFLAGS =/d" tools/gyp/pylib/gyp/generator/make.py || die
+
+ sed -i -e "/'-O3'/d" common.gypi node.gypi || die
+
+ # debug builds. change install path, remove optimisations and override buildtype
+ if use debug; then
+ sed -i -e "s|out/Release/|out/Debug/|g" tools/install.py || die
+ BUILDTYPE=Debug
+ fi
+
+ # We need to disable mprotect on two files when it builds Bug 694100.
+ use pax-kernel && PATCHES+=( "${FILESDIR}"/${PN}-20.6.0-paxmarking.patch )
+
+ default
+}
+
+src_configure() {
+ xdg_environment_reset
+
+ # LTO compiler flags are handled by configure.py itself
+ filter-lto
+ # nodejs unconditionally links to libatomic #869992
+ # specifically it requires __atomic_is_lock_free which
+ # is not yet implemented by llvm-runtimes/compiler-rt (see
+ # https://reviews.llvm.org/D85044?id=287068), therefore
+ # we depend on gcc and force using libgcc as the support lib
+ tc-is-clang && append-ldflags "--rtlib=libgcc --unwindlib=libgcc"
+
+ local myconf=(
+ --ninja
+ --shared-brotli
+ --shared-cares
+ --shared-libuv
+ --shared-nghttp2
+ --shared-ngtcp2
+ --shared-zlib
+ )
+ use debug && myconf+=( --debug )
+ use lto && myconf+=( --enable-lto )
+ if use system-icu; then
+ myconf+=( --with-intl=system-icu )
+ elif use icu; then
+ myconf+=( --with-intl=full-icu )
+ else
+ myconf+=( --with-intl=none )
+ fi
+ use corepack || myconf+=( --without-corepack )
+ use inspector || myconf+=( --without-inspector )
+ use npm || myconf+=( --without-npm )
+ use snapshot || myconf+=( --without-node-snapshot )
+ if use ssl; then
+ use system-ssl && myconf+=( --shared-openssl --openssl-use-def-ca-store )
+ else
+ myconf+=( --without-ssl )
+ fi
+
+ local myarch=""
+ case "${ARCH}:${ABI}" in
+ *:amd64) myarch="x64";;
+ *:arm) myarch="arm";;
+ *:arm64) myarch="arm64";;
+ loong:lp64*) myarch="loong64";;
+ riscv:lp64*) myarch="riscv64";;
+ *:ppc64) myarch="ppc64";;
+ *:x32) myarch="x32";;
+ *:x86) myarch="ia32";;
+ *) myarch="${ABI}";;
+ esac
+
+ GYP_DEFINES="linux_use_gold_flags=0
+ linux_use_bundled_binutils=0
+ linux_use_bundled_gold=0" \
+ "${EPYTHON}" configure.py \
+ --prefix="${EPREFIX}"/usr \
+ --dest-cpu=${myarch} \
+ "${myconf[@]}" || die
+}
+
+src_compile() {
+ eninja -C out/Release
+}
+
+src_install() {
+ local LIBDIR="${ED}/usr/$(get_libdir)"
+ default
+
+ pax-mark -m "${ED}"/usr/bin/node
+
+ # set up a symlink structure that node-gyp expects..
+ dodir /usr/include/node/deps/{v8,uv}
+ dosym . /usr/include/node/src
+ for var in deps/{uv,v8}/include; do
+ dosym ../.. /usr/include/node/${var}
+ done
+
+ if use doc; then
+ docinto html
+ dodoc -r "${S}"/doc/*
+ fi
+
+ if use npm; then
+ keepdir /etc/npm
+ echo "NPM_CONFIG_GLOBALCONFIG=${EPREFIX}/etc/npm/npmrc" > "${T}"/50npm
+ doenvd "${T}"/50npm
+
+ # Install bash completion for `npm`
+ local tmp_npm_completion_file="$(TMPDIR="${T}" mktemp -t npm.XXXXXXXXXX)"
+ "${ED}/usr/bin/npm" completion > "${tmp_npm_completion_file}"
+ newbashcomp "${tmp_npm_completion_file}" npm
+
+ # Move man pages
+ doman "${LIBDIR}"/node_modules/npm/man/man{1,5,7}/*
+
+ # Clean up
+ rm -f "${LIBDIR}"/node_modules/npm/{.mailmap,.npmignore,Makefile}
+
+ local find_exp="-or -name"
+ local find_name=()
+ for match in "AUTHORS*" "CHANGELOG*" "CONTRIBUT*" "README*" \
+ ".travis.yml" ".eslint*" ".wercker.yml" ".npmignore" \
+ "*.bat" "*.cmd"; do
+ find_name+=( ${find_exp} "${match}" )
+ done
+
+ # Remove various development and/or inappropriate files and
+ # useless docs of dependend packages.
+ find "${LIBDIR}"/node_modules \
+ \( -type d -name examples \) -or \( -type f \( \
+ -iname "LICEN?E*" \
+ "${find_name[@]}" \
+ \) \) -exec rm -rf "{}" \;
+ fi
+
+ use corepack &&
+ "${D}"/usr/bin/corepack enable --install-directory "${D}"/usr/bin
+
+ mv "${ED}"/usr/share/doc/node "${ED}"/usr/share/doc/${PF} || die
+}
+
+src_test() {
+ local drop_tests=(
+ test/parallel/test-dns.js
+ test/parallel/test-dns-resolveany-bad-ancount.js
+ test/parallel/test-dns-setserver-when-querying.js
+ test/parallel/test-dotenv.js
+ test/parallel/test-fs-mkdir.js
+ test/parallel/test-fs-read-stream.js
+ test/parallel/test-fs-utimes-y2K38.js
+ test/parallel/test-fs-watch-recursive-add-file.js
+ test/parallel/test-http2-client-set-priority.js
+ test/parallel/test-http2-priority-event.js
+ test/parallel/test-inspector-emit-protocol-event.js
+ test/parallel/test-inspector-network-domain.js
+ test/parallel/test-process-euid-egid.js
+ test/parallel/test-process-get-builtin.mjs
+ test/parallel/test-process-initgroups.js
+ test/parallel/test-process-setgroups.js
+ test/parallel/test-process-uid-gid.js
+ test/parallel/test-release-npm.js
+ test/parallel/test-socket-write-after-fin-error.js
+ test/parallel/test-strace-openat-openssl.js
+ test/parallel/test-tls-cert-regression.js
+ test/parallel/test-tls-client-getephemeralkeyinfo.js
+ test/parallel/test-tls-getcipher.js
+ test/parallel/test-tls-set-ciphers.js
+ test/parallel/test-tls-junk-closes-server.js
+ test/parallel/test-util-styletext.js
+ test/sequential/test-util-debug.js
+ )
+ use inspector || drop_tests+=( test/sequential/test-watch-mode.mjs )
+ rm -f "${drop_tests[@]}" || die "disabling tests failed"
+
+ out/${BUILDTYPE}/cctest || die
+ "${EPYTHON}" tools/test.py --mode=${BUILDTYPE,,} --flaky-tests=dontcare -J message parallel sequential || die
+}
+
+pkg_postinst() {
+ if use npm; then
+ ewarn "remember to run: source /etc/profile if you plan to use nodejs"
+ ewarn " in your current shell"
+ fi
+}
diff --git a/net-libs/tdlib/Manifest b/net-libs/tdlib/Manifest
index fd0ddcabc4c5..0ba0b57521b0 100644
--- a/net-libs/tdlib/Manifest
+++ b/net-libs/tdlib/Manifest
@@ -1,2 +1,2 @@
DIST tdlib-1.8.49_p20250510.tar.gz 5477630 BLAKE2B 4f42bdb5306bf16c5e8f7f13809c3d1aa6f4805584aa21c87a2fb342b6b56c6ee9a6d8e108fabe42c195aa5ad03a7fc1d880fbcf68c8452359cfdf5bede33f7a SHA512 c0ec498011b821d545904674ed3534a5a2be4b38025daa4bb4e9661ec62c1583bc1edadb1dae2bc2619dc50e72baf5a3690e9aed6e87b2c123ce27370d00d9ff
-DIST tdlib-1.8.55.tar.gz 5569844 BLAKE2B 6b21086991126df93ecbd101c914c085e96603e51d34a2ddda2f805f59f1152fb05fb99efe7b998e395f74a843c9e85e3be59935f1b367e9dc4f9081d839a929 SHA512 fca25e017e6bc27bcc0a69b35ad478a5acfc46b511917440c3e560c18378c3f4133c1c553eb9a0752db5328f61c5813312d653f4ad5e5d0284b7a79d4f480be8
+DIST tdlib-1.8.58.tar.gz 5623576 BLAKE2B ed1348c9de81517831fe2346e8a5b8fca7417d7cf5fed0579658e706c4cb0a374c213d2fd15d7a88cc6197b6f386cb9add9d7d40c67b5b5af187f4eebafb99c4 SHA512 9c4b258650a60ce2b04d1d73bc8ade323b0eed1304a6cc98aa559cb3ed773260b1cc8c856cc07d11d9e4bcb07225db20f4a84551d0a30afd43fade8c44a99f48
diff --git a/net-libs/tdlib/tdlib-1.8.49_p20250510.ebuild b/net-libs/tdlib/tdlib-1.8.49_p20250510-r1.ebuild
index 77515d12851b..9e053501604c 100644
--- a/net-libs/tdlib/tdlib-1.8.49_p20250510.ebuild
+++ b/net-libs/tdlib/tdlib-1.8.49_p20250510-r1.ebuild
@@ -19,7 +19,7 @@ IUSE="+tde2e test"
RESTRICT="!test? ( test )"
RDEPEND="
- dev-libs/openssl
+ dev-libs/openssl:=
virtual/zlib:=
"
DEPEND="${RDEPEND}"
diff --git a/net-libs/tdlib/tdlib-1.8.55.ebuild b/net-libs/tdlib/tdlib-1.8.58.ebuild
index 1f10152284fb..f7326dc42623 100644
--- a/net-libs/tdlib/tdlib-1.8.55.ebuild
+++ b/net-libs/tdlib/tdlib-1.8.58.ebuild
@@ -8,7 +8,7 @@ inherit cmake
DESCRIPTION="Cross-platform library for building Telegram clients"
HOMEPAGE="https://github.com/tdlib/td"
-MY_PV="7d257dcda5dd2c616c1146540ef51147c5bb2c69"
+MY_PV="282f96ca66421c348ed75aaca84471b3e39e64dd"
SRC_URI="https://github.com/tdlib/td/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/td-${MY_PV}"
@@ -19,7 +19,7 @@ IUSE="+tde2e test"
RESTRICT="!test? ( test )"
RDEPEND="
- dev-libs/openssl
+ dev-libs/openssl:=
virtual/zlib:=
"
DEPEND="${RDEPEND}"
generated by cgit v1.2.3 (git 2.25.1) at 2025-12-18 05:03:37 +0000