From dc9def88168bb1d982c9f3eb6441468e4fdd7b37 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Mon, 21 Aug 2023 19:06:05 +0100
Subject: dev-cpp/abseil-cpp: backport -std=c++14

Backport 6ad1e6f5375e93ff6c9053392852ed4ae0eac7c4.

Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-cpp/abseil-cpp/abseil-cpp-20230125.3-r1.ebuild | 66 ++++++++++++++++++++++
 dev-cpp/abseil-cpp/abseil-cpp-20230125.3.ebuild    | 64 ---------------------
 2 files changed, 66 insertions(+), 64 deletions(-)
 create mode 100644 dev-cpp/abseil-cpp/abseil-cpp-20230125.3-r1.ebuild
 delete mode 100644 dev-cpp/abseil-cpp/abseil-cpp-20230125.3.ebuild

(limited to 'dev-cpp/abseil-cpp')

diff --git a/dev-cpp/abseil-cpp/abseil-cpp-20230125.3-r1.ebuild b/dev-cpp/abseil-cpp/abseil-cpp-20230125.3-r1.ebuild
new file mode 100644
index 000000000000..3ab7ae818f50
--- /dev/null
+++ b/dev-cpp/abseil-cpp/abseil-cpp-20230125.3-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake-multilib python-any-r1
+
+DESCRIPTION="Abseil Common Libraries (C++), LTS Branch"
+HOMEPAGE="https://abseil.io/"
+SRC_URI="https://github.com/abseil/abseil-cpp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV%%.*}.0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		>=dev-cpp/gtest-1.13.0
+		sys-libs/timezone-data
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20230125.2-musl-1.2.4.patch #906218
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# un-hardcode abseil compiler flags
+	sed -i \
+		-e '/"-maes",/d' \
+		-e '/"-msse4.1",/d' \
+		-e '/"-mfpu=neon"/d' \
+		-e '/"-march=armv8-a+crypto"/d' \
+		absl/copts/copts.py || die
+
+	# now generate cmake files
+	python_fix_shebang absl/copts/generate_copts.py
+	absl/copts/generate_copts.py || die
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		# We use -std=c++14 here so that abseil-cpp's string_view is used
+		# See the discussion in https://github.com/gentoo/gentoo/pull/32281.
+		-DCMAKE_CXX_STANDARD=14
+		-DABSL_ENABLE_INSTALL=TRUE
+		-DABSL_USE_EXTERNAL_GOOGLETEST=ON
+		-DABSL_PROPAGATE_CXX_STD=TRUE
+		-DABSL_BUILD_TEST_HELPERS=$(usex test ON OFF)
+		-DABSL_BUILD_TESTING=$(usex test ON OFF)
+		$(usex test -DBUILD_TESTING=ON '') # intentional usex, it used both variables for tests.
+	)
+
+	cmake_src_configure
+}
diff --git a/dev-cpp/abseil-cpp/abseil-cpp-20230125.3.ebuild b/dev-cpp/abseil-cpp/abseil-cpp-20230125.3.ebuild
deleted file mode 100644
index 6314e6d2977e..000000000000
--- a/dev-cpp/abseil-cpp/abseil-cpp-20230125.3.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 2020-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-
-inherit cmake-multilib python-any-r1
-
-DESCRIPTION="Abseil Common Libraries (C++), LTS Branch"
-HOMEPAGE="https://abseil.io/"
-SRC_URI="https://github.com/abseil/abseil-cpp/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0/${PV%%.*}"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="test"
-
-DEPEND=""
-RDEPEND="${DEPEND}"
-
-BDEPEND="
-	${PYTHON_DEPS}
-	test? (
-		>=dev-cpp/gtest-1.13.0
-		sys-libs/timezone-data
-	)
-"
-
-RESTRICT="!test? ( test )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-20230125.2-musl-1.2.4.patch #906218
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# un-hardcode abseil compiler flags
-	sed -i \
-		-e '/"-maes",/d' \
-		-e '/"-msse4.1",/d' \
-		-e '/"-mfpu=neon"/d' \
-		-e '/"-march=armv8-a+crypto"/d' \
-		absl/copts/copts.py || die
-
-	# now generate cmake files
-	python_fix_shebang absl/copts/generate_copts.py
-	absl/copts/generate_copts.py || die
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_CXX_STANDARD=17
-		-DABSL_ENABLE_INSTALL=TRUE
-		-DABSL_USE_EXTERNAL_GOOGLETEST=ON
-		-DABSL_PROPAGATE_CXX_STD=TRUE
-		-DABSL_BUILD_TEST_HELPERS=$(usex test ON OFF)
-		-DABSL_BUILD_TESTING=$(usex test ON OFF)
-		$(usex test -DBUILD_TESTING=ON '') # intentional usex, it used both variables for tests.
-	)
-
-	cmake_src_configure
-}
-- 
cgit v1.2.3