From f85d1bffa0279796465f491474025801683ba10c Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 25 May 2025 23:51:14 +0100
Subject: dev-cpp/glog: add 0.7.1

Last release, it's been discontinued now (see README).

Closes: https://bugs.gentoo.org/863599
Closes: https://bugs.gentoo.org/945274
Closes: https://bugs.gentoo.org/954083
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-cpp/glog/glog-0.7.1.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-cpp/glog/glog-0.7.1.ebuild

(limited to 'dev-cpp/glog/glog-0.7.1.ebuild')

diff --git a/dev-cpp/glog/glog-0.7.1.ebuild b/dev-cpp/glog/glog-0.7.1.ebuild
new file mode 100644
index 000000000000..478208ff7077
--- /dev/null
+++ b/dev-cpp/glog/glog-0.7.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2011-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+DESCRIPTION="Google Logging library"
+HOMEPAGE="https://github.com/google/glog"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/google/glog"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="BSD"
+SLOT="0/2"
+IUSE="gflags +libunwind llvm-libunwind test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	gflags? ( dev-cpp/gflags:=[${MULTILIB_USEDEP}] )
+	libunwind? (
+		llvm-libunwind? ( llvm-runtimes/libunwind:=[${MULTILIB_USEDEP}] )
+		!llvm-libunwind? ( sys-libs/libunwind:=[${MULTILIB_USEDEP}] )
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.8.0[${MULTILIB_USEDEP}] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DWITH_GFLAGS=$(usex gflags ON OFF)
+		-DWITH_GTEST=$(usex test ON OFF)
+		-DWITH_UNWIND=$(usex libunwind ON OFF)
+	)
+
+	cmake-multilib_src_configure
+}
+
+src_test() {
+	# Tests have a history of being brittle: bug #863599
+	CMAKE_SKIP_TESTS=(
+		logging
+		stacktrace
+		symbolize
+		log_severity_conversion
+		includes_vlog_is_on
+		includes_raw_logging
+	)
+
+	cmake-multilib_src_test -j1
+}
-- 
cgit v1.2.3