From ad7f93d52342c57be176764b89aed9ae401c7f8a Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 27 Mar 2021 01:27:41 +0000
Subject: dev-cpp/libmcpp: (security) bump to 2.7.2_p5 (Debian)

Easier to just use the Debian patchset here.

Bug: https://bugs.gentoo.org/718808
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild | 50 +++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild

(limited to 'dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild')

diff --git a/dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild b/dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild
new file mode 100644
index 000000000000..bc6a9a1d2336
--- /dev/null
+++ b/dev-cpp/libmcpp/libmcpp-2.7.2_p5.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+MY_PN=${PN/lib/}
+MY_P=$(ver_cut 1-4 ${MY_PN}-${PV})
+
+DESCRIPTION="A portable C++ preprocessor"
+HOMEPAGE="http://mcpp.sourceforge.net"
+SRC_URI="mirror://sourceforge/mcpp/${MY_P}.tar.gz"
+SRC_URI+=" https://deb.debian.org/debian/pool/main/m/${MY_PN}/${MY_PN}_${PV/_p/-}.debian.tar.xz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~x86 ~x86-linux ~x64-macos"
+IUSE="static-libs"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.7.2-fix-build-system.patch
+)
+
+src_prepare() {
+	default
+
+	# bug #718808
+	eapply "${WORKDIR}"/debian/patches/*.patch
+
+	# bug #778461
+	sed -i 's/-lmcpp/libmcpp.la/' src/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-mcpplib \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	if ! use static-libs; then
+		find "${D}" -name '*.la' -delete || die
+	fi
+}
-- 
cgit v1.2.3