From 9a5aa74c29f7836c6f55d4ea67258a14dee1fa92 Mon Sep 17 00:00:00 2001
From: Alfred Wingate <parona@protonmail.com>
Date: Sat, 3 May 2025 16:47:07 +0300
Subject: dev-cpp/libxmlpp: add dev-libs/libxml2 subslot op for incoming ABI
 break

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/41919
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild | 58 ++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild

(limited to 'dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild')

diff --git a/dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild b/dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild
new file mode 100644
index 000000000000..2c4bcf287ad8
--- /dev/null
+++ b/dev-cpp/libxmlpp/libxmlpp-2.42.2-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="${PN/pp/++}"
+
+inherit gnome2 meson-multilib
+
+DESCRIPTION="C++ wrapper for the libxml2 XML parser library"
+HOMEPAGE="http://libxmlplusplus.sourceforge.net/"
+
+LICENSE="LGPL-2.1"
+SLOT="2.6"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libxml2-2.7.7:=[${MULTILIB_USEDEP}]
+	>=dev-cpp/glibmm-2.32.0:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		dev-cpp/mm-common
+		app-text/doxygen
+		media-gfx/graphviz
+		dev-libs/libxslt
+	)
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/install_docdir = /s/'doc'/'gtk-doc'/" \
+		docs/reference/meson.build || die
+	sed -i \
+		-e "/install_tutorialdir = /s/'doc'/'gtk-doc'/" \
+		docs/manual/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dmaintainer-mode=false
+		-Dwarnings=min
+		-Ddist-warnings=max
+		-Dbuild-deprecated-api=true
+		$(meson_native_use_bool doc build-documentation)
+		-Dvalidation=false
+		-Dbuild-pdf=false
+		-Dbuild-examples=false
+		$(meson_use test build-tests)
+		-Dmsvc14x-parallel-installable=false
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3