From b1b3acbbc831a578e1dfc171e9b39b5b9d191572 Mon Sep 17 00:00:00 2001
From: "Z. Liu" <zhixu.liu@gmail.com>
Date: Thu, 17 Apr 2025 15:22:33 +0800
Subject: dev-cpp/opentelemetry-cpp: bump to v1.20.0

Closes: https://bugs.gentoo.org/904503
Signed-off-by: Z. Liu <zhixu.liu@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/41626
Closes: https://github.com/gentoo/gentoo/pull/41626
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../opentelemetry-cpp-1.20.0.ebuild                | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.20.0.ebuild

(limited to 'dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.20.0.ebuild')

diff --git a/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.20.0.ebuild b/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.20.0.ebuild
new file mode 100644
index 000000000000..77c626523688
--- /dev/null
+++ b/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.20.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="The OpenTelemetry C++ Client"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://github.com/open-telemetry/opentelemetry-cpp
+"
+SRC_URI="https://github.com/open-telemetry/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+IUSE="prometheus test"
+
+RDEPEND="
+	net-misc/curl:=
+	dev-libs/boost:=
+"
+DEPEND="
+	${RDEPEND}
+	prometheus? (
+		dev-cpp/prometheus-cpp
+	)
+	test? (
+		dev-cpp/gtest
+		dev-cpp/benchmark
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	# remove tests the need network
+	"${FILESDIR}/${PN}-1.5.0-tests.patch"
+	"${FILESDIR}/${PN}-1.16.1-cstdint.patch"
+	"${FILESDIR}/${PN}-1.16.1-fix-clang-template.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+		-DBUILD_SHARED_LIBS:BOOL=ON
+		-DBUILD_TESTING:BOOL=$(usex test)
+		-DWITH_PROMETHEUS:BOOL=$(usex prometheus)
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3