From c4e5a39d99e8aeb622be55a9b4b0056238e860f9 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Wed, 18 May 2022 11:45:22 -0700
Subject: dev-cpp/opentelemetry-cpp: add 1.4.0

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 .../opentelemetry-cpp-1.4.0.ebuild                 | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.4.0.ebuild

(limited to 'dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.4.0.ebuild')

diff --git a/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.4.0.ebuild b/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.4.0.ebuild
new file mode 100644
index 000000000000..d37e2bfc376f
--- /dev/null
+++ b/dev-cpp/opentelemetry-cpp/opentelemetry-cpp-1.4.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="The OpenTelemetry C++ Client"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://github.com/open-telemetry/opentelemetry-cpp
+"
+SRC_URI="https://github.com/open-telemetry/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+jaeger prometheus test"
+
+RDEPEND="
+	net-misc/curl:=
+	dev-libs/thrift:=
+	dev-libs/boost:=
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-cpp/gtest
+		dev-cpp/benchmark
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	# remove tests the need network
+	"${FILESDIR}/opentelemetry-cpp-1.3.0-tests.patch"
+)
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
+		-DBUILD_SHARED_LIBS:BOOL=ON
+		-DBUILD_TESTING:BOOL=$(usex test)
+		-DWITH_JAEGER:BOOL=$(usex jaeger)
+		-DWITH_PROMETHEUS:BOOL=$(usex prometheus)
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3