From c4254e17b77cfae721a93704ab83e8c0e489c9c4 Mon Sep 17 00:00:00 2001
From: Oliver Freyermuth <o.freyermuth@googlemail.com>
Date: Sat, 17 Jun 2023 04:22:18 +0200
Subject: dev-cpp/scitokens-cpp: depend on dev-cpp/jwt-cpp[picojson]

This adds the missing explicit dependency on USE=picojson being enabled
for dev-cpp/jwt-cpp, and also conditionalizes sys-apps/util-linux with kernel_linux.

Closes: https://bugs.gentoo.org/908610
Closes: https://github.com/gentoo/gentoo/pull/31492
Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>
Signed-off-by: Guilherme Amadio <amadio@gentoo.org>
---
 .../scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild    |  4 +-
 .../scitokens-cpp/scitokens-cpp-1.0.2-r1.ebuild    | 57 ++++++++++++++++++++++
 dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2.ebuild   | 57 ----------------------
 3 files changed, 59 insertions(+), 59 deletions(-)
 create mode 100644 dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2-r1.ebuild
 delete mode 100644 dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2.ebuild

(limited to 'dev-cpp/scitokens-cpp')

diff --git a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild
index 19a7d9f94ecc..a2415f536fdd 100644
--- a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild
+++ b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild
@@ -21,11 +21,11 @@ SLOT="0"
 IUSE="test"
 
 DEPEND="
-	dev-cpp/jwt-cpp
+	dev-cpp/jwt-cpp[picojson]
 	dev-db/sqlite
 	dev-libs/openssl:0=
 	net-misc/curl:0=
-	sys-apps/util-linux
+	kernel_linux? ( sys-apps/util-linux )
 "
 RDEPEND="${DEPEND}"
 BDEPEND="
diff --git a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2-r1.ebuild b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..a2415f536fdd
--- /dev/null
+++ b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/scitokens/scitokens-cpp"
+else
+	SRC_URI="https://github.com/scitokens/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION=" A C++ implementation of the SciTokens library with a C library interface"
+HOMEPAGE="https://scitokens.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+
+DEPEND="
+	dev-cpp/jwt-cpp[picojson]
+	dev-db/sqlite
+	dev-libs/openssl:0=
+	net-misc/curl:0=
+	kernel_linux? ( sys-apps/util-linux )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-cpp/gtest )
+"
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	# Unbundle dev-cpp/gtest, dev-cpp/jwt-cpp
+	rm -r vendor || die
+	# Fix include path for picojson.
+	find src/ \( -name '*.cpp' -o -name '*.h' \) -type f -print0 | \
+		xargs -0 sed -r -e "s:picojson/picojson\.h:picojson.h:g" -i || die
+	# Disable network-based tests relying on external services.
+	if use test; then
+		sed -i	-e '/^TEST_F/s#RefreshTest#DISABLED_RefreshTest#' \
+			-e '/^TEST_F/s#RefreshExpiredTest#DISABLED_RefreshExpiredTest#' test/main.cpp || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSCITOKENS_BUILD_UNITTESTS="$(usex test)"
+		-DSCITOKENS_EXTERNAL_GTEST=YES
+	)
+	cmake_src_configure
+}
diff --git a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2.ebuild b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2.ebuild
deleted file mode 100644
index 19a7d9f94ecc..000000000000
--- a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.2.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake
-
-if [[ ${PV} == *9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/scitokens/scitokens-cpp"
-else
-	SRC_URI="https://github.com/scitokens/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-fi
-
-DESCRIPTION=" A C++ implementation of the SciTokens library with a C library interface"
-HOMEPAGE="https://scitokens.org/"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-IUSE="test"
-
-DEPEND="
-	dev-cpp/jwt-cpp
-	dev-db/sqlite
-	dev-libs/openssl:0=
-	net-misc/curl:0=
-	sys-apps/util-linux
-"
-RDEPEND="${DEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	test? ( dev-cpp/gtest )
-"
-RESTRICT="!test? ( test )"
-
-src_prepare() {
-	# Unbundle dev-cpp/gtest, dev-cpp/jwt-cpp
-	rm -r vendor || die
-	# Fix include path for picojson.
-	find src/ \( -name '*.cpp' -o -name '*.h' \) -type f -print0 | \
-		xargs -0 sed -r -e "s:picojson/picojson\.h:picojson.h:g" -i || die
-	# Disable network-based tests relying on external services.
-	if use test; then
-		sed -i	-e '/^TEST_F/s#RefreshTest#DISABLED_RefreshTest#' \
-			-e '/^TEST_F/s#RefreshExpiredTest#DISABLED_RefreshExpiredTest#' test/main.cpp || die
-	fi
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DSCITOKENS_BUILD_UNITTESTS="$(usex test)"
-		-DSCITOKENS_EXTERNAL_GTEST=YES
-	)
-	cmake_src_configure
-}
-- 
cgit v1.2.3