From a91e29a052cbd5df6d274033d090c9c3b34d0128 Mon Sep 17 00:00:00 2001
From: Matthias Maier <tamiko@gentoo.org>
Date: Tue, 17 May 2022 22:21:16 -0500
Subject: =?UTF-8?q?Rename=20dev-cpp/{cpp-taskflow=20=E2=86=92=20taskflow}?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Matthias Maier <tamiko@gentoo.org>
---
 dev-cpp/taskflow/taskflow-3.3.0.ebuild | 47 ++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-cpp/taskflow/taskflow-3.3.0.ebuild

(limited to 'dev-cpp/taskflow/taskflow-3.3.0.ebuild')

diff --git a/dev-cpp/taskflow/taskflow-3.3.0.ebuild b/dev-cpp/taskflow/taskflow-3.3.0.ebuild
new file mode 100644
index 000000000000..c131483350c0
--- /dev/null
+++ b/dev-cpp/taskflow/taskflow-3.3.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Modern C++ Parallel Task Programming"
+HOMEPAGE="https://taskflow.github.io"
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/taskflow/${PN}.git"
+	inherit git-r3
+	S="${WORKDIR}/taskflow-${PV}"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/taskflow-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-cpp/doctest )"
+
+HTML_DOCS=( docs/. )
+
+PATCHES=(
+	"${FILESDIR}"/taskflow-3.3.0-fix_doctest.patch
+)
+
+src_prepare() {
+	rm -r "${S}/3rd-party" || die "rm failed"
+	cmake_src_prepare
+}
+
+src_configure() {
+	# TODO: enable CUDA via USE flag
+	local mycmakeargs=(
+		-DTF_BUILD_CUDA=OFF
+		-DTF_BUILD_EXAMPLES=$(usex examples)
+		-DTF_BUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3