From b8a6b9b2e505277a7f4a82802dd43b6e5659e58d Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sun, 11 Aug 2019 20:09:59 +0200
Subject: dev-cpp/websocketpp: Port to EAPI 7

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild | 44 +++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild

(limited to 'dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild')

diff --git a/dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild b/dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..4578afc07baa
--- /dev/null
+++ b/dev-cpp/websocketpp/websocketpp-0.8.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="C++/Boost Asio based websocket client/server library"
+HOMEPAGE="https://www.zaphoyd.com/websocketpp"
+SRC_URI="https://github.com/zaphoyd/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-libs/boost )"
+RDEPEND="dev-libs/boost"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7.0-cmake-install.patch
+	"${FILESDIR}"/${PN}-0.8.1-boost-1.70.patch
+	# disable tests that are timing sensitive
+	# https://bugzilla.redhat.com/show_bug.cgi?id=1461069
+	"${FILESDIR}"/${PN}-0.8.1-disable-test_transport-test_transport_asio_timers.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CPP11=ON
+		-DBUILD_TESTS="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3