From 11bb8d734c0e97712bf844ea6ae90cadda696035 Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Thu, 2 Mar 2023 20:34:47 +0200
Subject: dev-embedded/dfu-programmer: add 1.0.0

Closes: https://bugs.gentoo.org/898652
Closes: https://bugs.gentoo.org/883241
Closes: https://github.com/gentoo/gentoo/pull/29902
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 .../dfu-programmer/dfu-programmer-1.0.0.ebuild     | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-embedded/dfu-programmer/dfu-programmer-1.0.0.ebuild

(limited to 'dev-embedded/dfu-programmer/dfu-programmer-1.0.0.ebuild')

diff --git a/dev-embedded/dfu-programmer/dfu-programmer-1.0.0.ebuild b/dev-embedded/dfu-programmer/dfu-programmer-1.0.0.ebuild
new file mode 100644
index 000000000000..59c09044f9ec
--- /dev/null
+++ b/dev-embedded/dfu-programmer/dfu-programmer-1.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools udev
+
+DESCRIPTION="A Device Firmware Update based USB programmer for Atmel chips"
+HOMEPAGE="
+	https://dfu-programmer.github.io/
+	https://sourceforge.net/projects/dfu-programmer/
+	https://github.com/dfu-programmer/dfu-programmer
+"
+
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+RDEPEND="
+	acct-group/plugdev
+	virtual/libusb:1
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	cat <<-EOF > 70-dfu-programmer.rules
+	#
+	# do not edit this file, it will be overwritten on update
+	#
+	EOF
+	printf 'SUBSYSTEM=="usb", ACTION=="add", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="%s", MODE="660", GROUP="plugdev", SYMLINK+="dfu-%%n"\n' \
+		2ff{a,b,9,7,4,3} >> 70-dfu-programmer.rules
+
+	udev_dorules 70-dfu-programmer.rules
+}
+
+pkg_postinst() {
+	udev_reload
+
+	elog "To update device firmware as user you must be in the plugdev group:"
+	elog
+	elog "usermod -aG plugdev <user>"
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3