From ff748764eca8a5f7e1570eb33ef0b84958f682b5 Mon Sep 17 00:00:00 2001
From: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Date: Tue, 10 Dec 2024 15:25:47 +0000
Subject: dev-lua/binaryheap: new package, add 0.4

dep for dev-lua/lua-http

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-lua/binaryheap/binaryheap-0.4.ebuild | 65 ++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-lua/binaryheap/binaryheap-0.4.ebuild

(limited to 'dev-lua/binaryheap/binaryheap-0.4.ebuild')

diff --git a/dev-lua/binaryheap/binaryheap-0.4.ebuild b/dev-lua/binaryheap/binaryheap-0.4.ebuild
new file mode 100644
index 000000000000..8ac436b21d4d
--- /dev/null
+++ b/dev-lua/binaryheap/binaryheap-0.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua
+
+MY_PN="${PN}.lua"
+MY_PV="version_$(ver_rs 1 v)"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="Binary heap implementation in pure Lua"
+HOMEPAGE="http://tieske.github.io/binaryheap.lua"
+HOMEPAGE+=" https://github.com/Tieske/binaryheap.lua"
+SRC_URI="https://github.com/Tieske/${MY_PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	test? (
+		dev-lua/busted[${LUA_USEDEP}]
+		dev-lua/luacov[${LUA_USEDEP}]
+	)
+"
+
+src_prepare() {
+	default
+	lua_copy_sources
+}
+
+lua_src_test() {
+	if [[ ${ELUA} == "lua5.3" ]]; then
+		# this test failed only with 5.3
+		rm "${BUILD_DIR}"/spec/dijkstras_algorithm_spec.lua || die
+	fi
+	busted --lua="${ELUA}" --output="plainTerminal" "${BUILD_DIR}"/spec || die "Tests fail with ${ELUA}"
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins src/${PN}.lua
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+	local HTML_DOCS=( docs )
+	dodoc -r "examples"
+	einstalldocs
+}
-- 
cgit v1.2.3