From 0dec450a90c7490f11df7e69cd9c6709c099285c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 13 Mar 2020 10:26:35 +0100
Subject: =?UTF-8?q?Move=20dev-python/{git-python=20=E2=86=92=20GitPython}?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Use upstream package name, especially that there is another package
called 'git-python' on PyPI.

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/GitPython/GitPython-3.1.0.ebuild | 59 +++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/GitPython/GitPython-3.1.0.ebuild

(limited to 'dev-python/GitPython/GitPython-3.1.0.ebuild')

diff --git a/dev-python/GitPython/GitPython-3.1.0.ebuild b/dev-python/GitPython/GitPython-3.1.0.ebuild
new file mode 100644
index 000000000000..586d0abb46de
--- /dev/null
+++ b/dev-python/GitPython/GitPython-3.1.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_PN=GitPython
+MY_P=${MY_PN}-${PV}
+GITDB_P=gitdb-4.0.2
+SMMAP_P=smmap-3.0.1
+
+DESCRIPTION="Library used to interact with Git repositories"
+HOMEPAGE="https://github.com/gitpython-developers/GitPython https://pypi.org/project/GitPython/"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz
+	test? (
+		https://dev.gentoo.org/~mgorny/dist/${MY_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${GITDB_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${SMMAP_P}.gitbundle
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+
+	git clone "${DISTDIR}/${MY_P}.gitbundle" "${T}"/test || die
+	git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb || die
+	git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
+
+	cd "${T}"/test || die
+	# remove performance tests
+	rm -r git/test/performance || die
+	# tests requiring network access
+	sed -i -e 's:test_fetch_error:_&:' git/test/test_remote.py || die
+	# broken apparently
+	sed -i -e 's:test_rev_parse:_&:' git/test/test_repo.py || die
+
+	distutils-r1_src_test
+}
-- 
cgit v1.2.3