From 45698164c4b52ee6a080bf993b9fd6d1f2e393c2 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 14 Jul 2020 13:31:31 +0200
Subject: dev-python/GitPython: Bump to 3.1.7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/GitPython/GitPython-3.1.7.ebuild | 58 +++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/GitPython/GitPython-3.1.7.ebuild

(limited to 'dev-python/GitPython/GitPython-3.1.7.ebuild')

diff --git a/dev-python/GitPython/GitPython-3.1.7.ebuild b/dev-python/GitPython/GitPython-3.1.7.ebuild
new file mode 100644
index 000000000000..2dedec128a2b
--- /dev/null
+++ b/dev-python/GitPython/GitPython-3.1.7.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+TEST_P=GitPython-${PV}
+GITDB_P=gitdb-4.0.5
+SMMAP_P=smmap-3.0.4
+
+DESCRIPTION="Library used to interact with Git repositories"
+HOMEPAGE="https://github.com/gitpython-developers/GitPython https://pypi.org/project/GitPython/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz
+	test? (
+		https://dev.gentoo.org/~mgorny/dist/${TEST_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${GITDB_P}.gitbundle
+		https://dev.gentoo.org/~mgorny/dist/${SMMAP_P}.gitbundle
+	)"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+
+	git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
+	git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb || die
+	git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
+
+	cd "${T}"/test || die
+	rm -r test/performance || die
+	# tests requiring network access
+	sed -i -e 's:test_fetch_error:_&:' test/test_remote.py || die
+	rm test/test_installation.py || die
+	# broken apparently (also fails in git clone)
+	sed -e 's:test_rev_parse:_&:' \
+		-i test/test_repo.py || die
+
+	distutils-r1_src_test
+}
-- 
cgit v1.2.3