From 601ff8e7c43f665f613c7130dfc67e5695f2667a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Maciej=20Bar=C4=87?= <xgqt@gentoo.org>
Date: Sun, 14 Apr 2024 16:52:53 +0200
Subject: dev-python/OutputCheck: enable py3.12 compat
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/929474
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild | 38 ++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild

(limited to 'dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild')

diff --git a/dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild b/dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild
new file mode 100644
index 000000000000..01ac4eea4db6
--- /dev/null
+++ b/dev-python/OutputCheck/OutputCheck-0.4.2-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool for checking the output of console programs inspired by LLVM's FileCheck"
+HOMEPAGE="https://github.com/stp/OutputCheck/"
+SRC_URI="https://github.com/stp/${PN}/archive/${PV}.tar.gz
+	-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/lit[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}/${PN}-0.4.2-Driver.patch" )
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Remove bad tests.
+	rm "${S}/tests/invalid-regex-syntax.smt2" || die "failed to remove bad tests"
+
+	# Create RELEASE-VERSION file.
+	echo "${PV}" > "${S}/RELEASE-VERSION" || die "failed to write RELEASE-VERSION"
+}
+
+python_test() {
+	lit --verbose "${S}/tests" || die "running test with ${EPYTHON} failed"
+}
-- 
cgit v1.2.3