From dadcdfa7ad46cbe8c8db85d43fd58c9a3bd04f12 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Thu, 2 Jun 2022 08:26:06 +0200
Subject: dev-python/PyPDF2: Bump to 2.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/PyPDF2/PyPDF2-2.0.0.ebuild | 56 +++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/PyPDF2/PyPDF2-2.0.0.ebuild

(limited to 'dev-python/PyPDF2/PyPDF2-2.0.0.ebuild')

diff --git a/dev-python/PyPDF2/PyPDF2-2.0.0.ebuild b/dev-python/PyPDF2/PyPDF2-2.0.0.ebuild
new file mode 100644
index 000000000000..60ab6293e3a3
--- /dev/null
+++ b/dev-python/PyPDF2/PyPDF2-2.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=41b5cd4f774f8fbd8ac42d93b9962f0376352a15
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/PyPDF2/
+	https://github.com/py-pdf/PyPDF2/
+"
+SRC_URI="
+	https://github.com/py-pdf/PyPDF2/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${P}"/sample-files/ || die
+	fi
+}
+
+src_install() {
+	if use examples; then
+		docinto examples
+		dodoc -r Sample_Code/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_src_install
+}
-- 
cgit v1.2.3