From 68942c8f48771db05d7b05e9ff0d4825c83ed306 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 22 Aug 2020 10:08:11 +0200
Subject: dev-python/PyQt5-sip: Revert "Remove redundant versions"
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Reverts: 7dc25e7317f8f75a5dff95613d72a2b15f474a05
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild | 90 ++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild

(limited to 'dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild')

diff --git a/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild b/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild
new file mode 100644
index 000000000000..c61529a6f32a
--- /dev/null
+++ b/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+inherit python-r1 toolchain-funcs
+
+DESCRIPTION="Private sip module for PyQt5"
+HOMEPAGE="https://www.riverbankcomputing.com/software/sip/intro"
+
+MY_PN=sip
+MY_P=${MY_PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+
+# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h
+SLOT="0/12"
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	!<dev-python/PyQt5-5.12.2
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# Sub-slot sanity check
+	local sub_slot=${SLOT#*/}
+	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h || die)
+	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
+		eerror
+		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
+		eerror "Please update SLOT variable as follows:"
+		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
+		eerror
+		die "sub-slot sanity check failed"
+	fi
+
+	default
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--sip-module PyQt5.sip
+			--sysroot="${ESYSROOT}/usr"
+			--no-tools
+			AR="$(tc-getAR) cqs"
+			CC="$(tc-getCC)"
+			CFLAGS="${CFLAGS}"
+			CFLAGS_RELEASE=
+			CXX="$(tc-getCXX)"
+			CXXFLAGS="${CXXFLAGS}"
+			CXXFLAGS_RELEASE=
+			LINK="$(tc-getCXX)"
+			LINK_SHLIB="$(tc-getCXX)"
+			LFLAGS="${LDFLAGS}"
+			LFLAGS_RELEASE=
+			RANLIB=
+			STRIP=
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake DESTDIR="${D}" install
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+}
-- 
cgit v1.2.3