From 941761bdef4dc05d94c47f5597c23db16cd943f7 Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Sat, 29 May 2021 10:19:43 +0200
Subject: dev-python/PyQtWebEngine: add 5.15.4, add py3.10

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 .../PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild      | 74 ++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild

(limited to 'dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild')

diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild
new file mode 100644
index 000000000000..5ba44ef3adfd
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro"
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/PyQt5-${PV}[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-sip-4.19.22:=[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtwebengine:5[widgets]
+"
+DEPEND="${RDEPEND}
+	>=dev-python/sip-4.19.22[${PYTHON_USEDEP}]
+"
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${EPYTHON}"
+			"${S}"/configure.py
+			--qmake="$(qt5_get_bindir)"/qmake
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Fix parallel install failure
+		sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets install_pep484_stubs install_api' \
+			${PN}.pro || die
+
+		# Run eqmake to respect toolchain and build flags
+		eqmake5 -recursive ${PN}.pro
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+}
-- 
cgit v1.2.3