From 0ffe4c0f4ddae231f7c9deb61bb22ec80d9dfab9 Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Sat, 28 Nov 2015 10:12:19 +0100
Subject: dev-python/coverage: Version Bump

Package-Manager: portage-2.2.25
Signed-off-by: Justin Lecher <jlec@gentoo.org>
---
 dev-python/coverage/coverage-4.0.3.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-python/coverage/coverage-4.0.3.ebuild

(limited to 'dev-python/coverage/coverage-4.0.3.ebuild')

diff --git a/dev-python/coverage/coverage-4.0.3.ebuild b/dev-python/coverage/coverage-4.0.3.ebuild
new file mode 100644
index 000000000000..78999a325718
--- /dev/null
+++ b/dev-python/coverage/coverage-4.0.3.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Code coverage measurement for Python"
+HOMEPAGE="http://nedbatchelder.com/code/coverage/ https://pypi.python.org/pypi/coverage"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="
+	>=dev-python/setuptools-18.4[${PYTHON_USEDEP}]
+	test? (
+		dev-python/PyContracts[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile() {
+	if [[ ${EPYTHON} == python2.7 ]]; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		export CFLAGS
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	[[ "${PYTHON}" =~ pypy ]] && export COVERAGE_NO_EXTENSION=no
+	${PYTHON} "${S}"/igor.py test_with_tracer py || die
+	${PYTHON} "${S}"/igor.py test_with_tracer c || die
+}
-- 
cgit v1.2.3