From 2ec1112dbeaab435adfe91a9739696be10f6647e Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 26 Jul 2025 06:53:33 +0200
Subject: dev-python/django-debug-toolbar: Bump to 6.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../django-debug-toolbar-6.0.0.ebuild              | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 dev-python/django-debug-toolbar/django-debug-toolbar-6.0.0.ebuild

(limited to 'dev-python/django-debug-toolbar/django-debug-toolbar-6.0.0.ebuild')

diff --git a/dev-python/django-debug-toolbar/django-debug-toolbar-6.0.0.ebuild b/dev-python/django-debug-toolbar/django-debug-toolbar-6.0.0.ebuild
new file mode 100644
index 000000000000..e0253c3be237
--- /dev/null
+++ b/dev-python/django-debug-toolbar/django-debug-toolbar-6.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A configurable set of panels that display various debug information"
+HOMEPAGE="
+	https://github.com/django-commons/django-debug-toolbar/
+	https://pypi.org/project/django-debug-toolbar/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-4.2.9[${PYTHON_USEDEP}]
+	elibc_musl? ( dev-python/tzdata )
+"
+
+BDEPEND="
+	test? (
+		dev-python/django-template-partials[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# requires django-csp
+	rm tests/test_csp_rendering.py || die
+}
+
+python_test() {
+	"${EPYTHON}" -m django test -v 2 --settings tests.settings tests \
+		|| die "Tests failed with ${EPYTHON}"
+}
-- 
cgit v1.2.3