From 83f924ebad8639230c6087276a162c1f72454f3d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 12 Oct 2021 07:57:28 +0200
Subject: dev-python/google-api-python-client: Bump to 2.25.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../google-api-python-client-2.25.0.ebuild         | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/google-api-python-client/google-api-python-client-2.25.0.ebuild

(limited to 'dev-python/google-api-python-client/google-api-python-client-2.25.0.ebuild')

diff --git a/dev-python/google-api-python-client/google-api-python-client-2.25.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.25.0.ebuild
new file mode 100644
index 000000000000..2bf8009bdc63
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.25.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-4[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+src_prepare() {
+	find tests -name '*.py' -exec \
+		sed -i -e 's:unittest2 as ::' {} + || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local deselect=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest tests ${deselect[@]/#/--deselect }
+}
-- 
cgit v1.2.3