From b7ce516db26a4dbdc9a600f22e5c461cc5b61933 Mon Sep 17 00:00:00 2001
From: Alfred Wingate <parona@protonmail.com>
Date: Sun, 21 Sep 2025 00:09:42 +0300
Subject: dev-python/gst-python: add 1.24.13

Bug: https://bugs.gentoo.org/951613
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 dev-python/gst-python/gst-python-1.24.13.ebuild | 68 +++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 dev-python/gst-python/gst-python-1.24.13.ebuild

(limited to 'dev-python/gst-python/gst-python-1.24.13.ebuild')

diff --git a/dev-python/gst-python/gst-python-1.24.13.ebuild b/dev-python/gst-python/gst-python-1.24.13.ebuild
new file mode 100644
index 000000000000..9c47bc724e9a
--- /dev/null
+++ b/dev-python/gst-python/gst-python-1.24.13.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit meson python-r1 xdg-utils
+
+DESCRIPTION="A Python Interface to GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=media-libs/gstreamer-${PV}:1.0[introspection]
+	>=media-libs/gst-plugins-base-${PV}:1.0[introspection]
+	>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/gstreamer_compat__ge_pygobject-3.52.3.patch"
+)
+
+src_prepare() {
+	default
+
+	# Avoid building & testing plugin - it must NOT be multi-python as gst-inspect will map in all libpython.so versions
+	# and crash or behave mysteriously.
+	# Python plugin support is of limited use (GIL gets in the way). If it's ever requested or needed, it should be a
+	# separate python-single-r1 media-plugins/gst-plugins-python package that only builds the plugin directory.
+	sed -e '/subdir.*plugin/d' -i meson.build || die
+	sed -e '/test_plugin.py/d' -i testsuite/meson.build || die
+
+	xdg_environment_reset
+}
+
+src_configure() {
+	configuring() {
+		meson_src_configure \
+			-Dpython="${EPYTHON}"
+	}
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test
+}
+
+src_install() {
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+}
-- 
cgit v1.2.3