From cfe48cae9702138c1ce11095bb5f64d1631b8026 Mon Sep 17 00:00:00 2001
From: Virgil Dupras <vdupras@gentoo.org>
Date: Mon, 29 Apr 2019 14:55:02 -0400
Subject: dev-python/ipython: bump to 7.5.0

Closes: https://bugs.gentoo.org/669408
Closes: https://bugs.gentoo.org/628260
Closes: https://bugs.gentoo.org/672372
Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11
---
 dev-python/ipython/ipython-7.5.0.ebuild | 150 ++++++++++++++++++++++++++++++++
 1 file changed, 150 insertions(+)
 create mode 100644 dev-python/ipython/ipython-7.5.0.ebuild

(limited to 'dev-python/ipython/ipython-7.5.0.ebuild')

diff --git a/dev-python/ipython/ipython-7.5.0.ebuild b/dev-python/ipython/ipython-7.5.0.ebuild
new file mode 100644
index 000000000000..aa8770cf42f0
--- /dev/null
+++ b/dev-python/ipython/ipython-7.5.0.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 eutils virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+# About "-python_targets_python2_7":
+# The ipython stack is in a tricky transition to py3-only. It has many circular
+# dependencies which causes a chicken-and-egg problem because for Portage to
+# properly handle dependency resolution on a system with
+# python_targets_python2_7 all members of the circular dependency must go
+# py3-only at the same time. If they don't, the dependency that requires py2
+# will seek older ipython releases for resolution. This is why, for members
+# of the circular dependency, we force -python_targets_python2_7. This way, the
+# circle stays firmly in py3-only land. This only affects members of the
+# circular dependency. Other dependencies can be on py2 without problem.
+#
+# This situation also require us to explicitly depend on transitive dependencies
+# that are part of the circular dependecy so that we preserve "circle
+# integrity". It's a bit ugly, but temporary.
+
+CDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/jedi[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-2.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP},-python_targets_python2_7] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP},-python_targets_python2_7] )"
+
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP},-python_targets_python2_7]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP},-python_targets_python2_7]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP},-python_targets_python2_7]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP},-python_targets_python2_7]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP},-python_targets_python2_7]
+		dev-python/notebook[${PYTHON_USEDEP},-python_targets_python2_7]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
-- 
cgit v1.2.3